Cenário de persistência do conjunto de registros do XML

Aplica-se ao: Access 2013, Office 2013

Neste cenário, você criará um aplicativo ASP (Active Server Pages) que salva o conteúdo de um objeto Recordset diretamente no objeto Response ASP.

Observação

[!OBSERVAçãO] Este cenário exige que seu servidor tenha o IIS 5.0 (Internet Information Server) ou posterior instalado.

O Recordset retornado é exibido no Internet Explorer usando um RDS.DataControl.

As seguintes etapas são necessárias para criar este cenário:

  1. Configurar o aplicativo.
  2. Obter os dados.
  3. Enviar os dados.
  4. Receber e exibir os dados.

Etapa 1: Configurar o aplicativo

  1. Crie um diretório virtual IIS chamado XMLPersist com permissões de script.

  2. Crie dois novos arquivos de texto na pasta para a qual o diretório virtual aponta, um chamado XMLResponse.asp e outro chamado Default.htm.

Etapa 2: obter os dados

Nesta etapa, você gravará o código para abrir um Recordset ADO e preparar para enviá-lo ao cliente.

  1. Abra o arquivo XMLResponse.asp com um editor de texto, como o Bloco de Notas do Windows, e insira o seguinte código:

    
     <%@ language="VBScript" %> 

     <!-- #include file='adovbs.inc' --> 

     <% 
     Dim strSQL, strCon 
     Dim adoRec  
     Dim adoCon  
     Dim xmlDoc  

     ' You will need to change "slqServer" below to the name of the SQL  
     ' server machine to which you want to connect. 
     strCon = "Provider=sqloledb;Data Source=sqlServer;Initial Catalog=Pubs;Integrated Security=SSPI;" 
     Set adoCon = server.createObject("ADODB.Connection") 
     adoCon.Open strCon 

     strSQL = "SELECT Title, Price FROM Titles ORDER BY Price" 
     Set adoRec = Server.CreateObject("ADODB.Recordset") 
     adoRec.Open strSQL, adoCon, adOpenStatic, adLockOptimistic, adCmdText

  2. Certifique-se de alterar o valor do parâmetro Fonte de Dados em strCon para o nome do seu computador com Microsoft SQL Server.

  3. Mantenha o arquivo aberto e vá para a próxima etapa.

Etapa 3: Enviar os dados

Agora que você tem um Recorset, você precisa enviá-lo ao cliente, salvando-o como XML no objeto Response ASP.

  1. Adicione o seguinte código na parte inferior do XMLResponse.asp:

    
 Response.ContentType = "text/xml" 
 Response.Expires = 0 
 Response.Buffer = False 


 Response.Write "<?xml version='1.0'?>" & vbNewLine 
 adoRec.save Response, adPersistXML 
 adoRec.Close 
 Set adoRec=Nothing 
 %>

    Observe que o objeto Response ASP é especificado como o destino para o método Save do Recordset. O destino do método Save pode ser qualquer objeto que ofereça suporte à interface IStream, como um objeto Stream ADO ou um nome de arquivo que inclui o caminho completo no qual o Recordset deve ser salvo.

  2. Salve e feche o arquivo XMLResponse.asp antes de ir para a próxima etapa. Copie também o arquivo adovbs.inc da pasta C:\Program Files\Common Files\System\Ado para a mesma pasta na qual está o arquivo XMLResponse.asp.

Etapa 4: receber e exibir os dados

Nesta etapa, você criará um arquivo HTML com um RDS incorporado. DataControl que aponta para o arquivo XMLResponse.asp para obter o Recordset.

  1. Abra default.htm com um editor de texto, como o Bloco de Notas do Windows, e adicione o código a seguir. Substitua "sqlserver" no URL pelo nome do seu computador servidor.

    
 <HTML> 
 <HEAD><TITLE>ADO Recordset Persistence Sample</TITLE></HEAD> 
 <BODY> 

 <TABLE DATASRC="#RDC1" border="1"> 
 <TR> 
 <TD><SPAN DATAFLD="title"></SPAN></TD> 
 <TD><SPAN DATAFLD="price"></SPAN></TD> 
 </TR> 
 </TABLE> 

 <OBJECT CLASSID="clsid:BD96C556-65A3-11D0-983A-00C04FC29E33" ID="RDC1"> 
 <PARAM NAME="URL" VALUE="XMLResponse.asp"> 
 </OBJECT> 

 </BODY> 
 </HTML>

  2. Feche o arquivo default.htm e salve-o na mesma pasta na qual você salvou o arquivo XMLResponse.asp.

  3. Usando o Internet Explorer 4.0 ou posterior, abra a URL https://<sqlserver>/XMLPersist/default.htm e observe os resultados. Os dados são exibidos em uma tabela DHTML vinculada.

  4. Agora abra a URL https://<sqlserver>/XMLPersist/XMLResponse.asp e observe os resultados. O XML é exibido.

  • Last updated on