Objeto AddIn (Excel)

Representa um único suplemento, instalado ou não.

Comentários

O objeto AddIn é um membro da coleção AddIns. A coleção AddIns contém uma lista de todos os suplementos disponíveis para o Microsoft Excel, independentemente de estarem ou não instalados. Essa lista corresponde à lista de suplementos exibidos na caixa de diálogo Suplementos.

Exemplo

Use Suplementos (índice), onde índice é o título do suplemento ou o número de índice, para retornar um único objeto do Suplemento . O exemplo a seguir instala o suplemento Ferramentas de Análise.

AddIns("analysis toolpak").Installed = True

Não confunda o título do suplemento, que aparece na caixa de diálogo Suplementos , com o nome do suplemento, que é o nome do arquivo do suplemento. Você deve soletrar o título do suplemento exatamente como está escrito na caixa de diálogo Suplementos , mas o uso de maiúsculas não precisa corresponder.

O número de índice representa a posição do suplemento na caixa Suplementos disponíveis da caixa de diálogo Suplementos. O exemplo a seguir cria uma lista que contém propriedades especificadas dos suplementos disponíveis.

With Worksheets("sheet1") 
 .Rows(1).Font.Bold = True 
 .Range("a1:d1").Value = _ 
 Array("Name", "Full Name", "Title", "Installed") 
 For i = 1 To AddIns.Count 
 .Cells(i + 1, 1) = AddIns(i).Name 
 .Cells(i + 1, 2) = AddIns(i).FullName 
 .Cells(i + 1, 3) = AddIns(i).Title 
 .Cells(i + 1, 4) = AddIns(i).Installed 
 Next 
 .Range("a1").CurrentRegion.Columns.AutoFit 
End With

O método Add adiciona um suplemento à lista de suplementos disponíveis, mas não instala o suplemento. Defina a propriedade Installed do suplemento como True para instalá-lo.

Para instalar um suplemento que não aparece na lista de suplementos disponíveis, primeiro você deve usar o método Add e, em seguida, definir a propriedade Installed . Isso pode ser feito em uma única etapa, como mostra o exemplo a seguir (observe que você usa o nome do suplemento, e não seu título, com o método Add).

AddIns.Add("generic.xll").Installed = True

Use Pastas de Trabalho (índice), onde índice é o nome do arquivo de suplemento (não o título) para retornar uma referência à pasta de trabalho correspondente a um suplemento carregado. Você deve usar o nome do arquivo porque suplementos carregados normalmente não aparecem na coleção de pastas de trabalho . Este exemplo define a variável wb como a pasta de trabalho de Myaddin.xla.

Set wb = Workbooks("myaddin.xla")

O exemplo a seguir define a variável wb como a pasta de trabalho do suplemento Ferramentas de Análise.

Set wb = Workbooks(AddIns("analysis toolpak").Name)

Se a propriedade Installed retornar True, mas as chamadas para funções no suplemento ainda falharem, talvez o suplemento não esteja realmente carregado. Isso ocorre porque o objeto Addin representa a existência e o estado instalado do suplemento, mas não representa o conteúdo real da pasta de trabalho do suplemento. Para garantir que um suplemento instalado seja carregado, você deve abrir a pasta de trabalho do suplemento.

O exemplo a seguir abre a pasta de trabalho do suplemento chamado "Meu Suplemento" se o suplemento ainda não estiver presente na coleção de Pastas de Trabalho .

On Error Resume Next ' turn off error checking 
Set wbMyAddin = Workbooks(AddIns("My Addin").Name) 
lastError = Err 
On Error Goto 0 ' restore error checking 
If lastError <> 0 Then 
 ' the add-in workbook isn't currently open. Manually open it. 
 Set wbMyAddin = Workbooks.Open(AddIns("My Addin").FullName) 
End If

Propriedades

Confira também

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on