Método CalculatedMembers.Add (Excel)

Adiciona um campo ou item calculado a uma tabela dinâmica. Retorna um objeto CalculatedMember .

Sintaxe

mais simples. Add (Name, Formula, SolveOrder, Type, Dynamic, DisplayFolder, HierarchizeDistinct)

expressão Uma variável que representa um objeto CalculatedMembers .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
Name Obrigatório String O nome do membro calculado.
Fórmula Obrigatório String A fórmula do membro calculado.
SolveOrder Opcional Variant A ordem de resolução do membro calculado.
Type Opcional Variant O tipo do membro calculado.
Dynamic Opcional Boolean Especifica se o membro calculado é recalculado a cada atualização.
DisplayFolder Opcional String O nome da pasta de exibição do membro calculado.
HierarchizeDistinct Opcional Boolean Especifica se deseja ordenar e remover duplicatas ao exibir a hierarquia do membro calculado em um relatório de Tabela Dinâmica baseado em um cubo OLAP.

Valor de retorno

Um objeto CalculatedMember que representa o novo campo ou item calculado.

Comentários

O argumento Formula deve conter uma instrução de sintaxe MDX (Multidimensional Expression) válida. O argumento Nome deve ser aceitável para o provedor OLAP (Processamento Analítico Online) e o argumento Tipo deve ser definido.

Se você definir o argumento Type desse método como xlCalculatedSet, deverá chamar o método AddSet do objeto CubeFields para tornar o novo conjunto de campos visível na Tabela Dinâmica.

Exemplo

O exemplo a seguir adiciona um conjunto a uma tabela dinâmica.

Observação

A conexão com o cubo e a Tabela Dinâmica existente é necessária para que o exemplo seja executado.

Sub UseAddSet() 
 
 Dim pvtOne As PivotTable 
 Dim strAdd As String 
 Dim strFormula As String 
 Dim cbfOne As CubeField 
 
 Set pvtOne = ActiveSheet.PivotTables(1) 
 
 strAdd = "[MySet]" 
 strFormula = "'{[Product].[All Products].[Food].children}'" 
 
 ' Establish connection with data source if necessary. 
 If Not pvtOne.PivotCache.IsConnected Then pvtOne.PivotCache.MakeConnection 
 
 ' Add a calculated member titled "[MySet]" 
 pvtOne.CalculatedMembers.Add Name:=strAdd, _ 
 Formula:=strFormula, Type:=xlCalculatedSet 
 
 ' Add a set to the CubeField object. 
 Set cbfOne = pvtOne.CubeFields.AddSet(Name:="[MySet]", _ 
 Caption:="My Set") 
 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on