Propriedade Shape.TextFrame2 (Project)

Obtém um objeto TextFrame2 que contém o texto em um quadro de texto e os membros que controlam o alinhamento, a ancoragem e outros recursos do quadro de texto. TextFrame2 somente leitura.

Sintaxe

mais simples. TextFrame2

expressão Uma variável que representa um objeto Shape.

Comentários

Um objeto TextFrame2 contém muitas das mesmas propriedades que um objeto TextFrame , além de propriedades adicionais, como AutoSize, ThreeD e WordArtformat.

Exemplo

O exemplo a seguir cria duas caixas de texto e as adiciona a um objeto ShapeRange , define os dois quadros de texto para se ajustarem automaticamente ao texto, define a cor do primeiro plano do texto na forma da primeira caixa de texto como vermelho, define a cor do primeiro plano do intervalo de formas para um bronzeado amarelado e, em seguida, usa a propriedade TextEffect para definir as propriedades de fonte em ambas as caixas de texto no intervalo de formas.

A propriedade TextFrame2 para os objetos Shape individuais é mostrada em negrito.

Sub FormatTextBox()
    Dim theReport As Report
    Dim textShape1 As shape
    Dim textShape2 As shape
    Dim reportName As String
    Dim sRange As ShapeRange
    
    reportName = "Textbox range report"
    
    Set theReport = ActiveProject.Reports.Add(reportName)
    Set textShape1 = theReport.Shapes.AddTextbox(msoTextOrientationHorizontal, 30, 50, 350, 80)
    textShape1.Name = "Text box 1"
    
    Set textShape2 = theReport.Shapes.AddTextbox(msoTextOrientationHorizontal, 30, 130, 350, 80)
    textShape2.Name = "Text box 2"
    
    Set sRange = theReport.Shapes.Range(Array("Text box 1", "Text box 2"))
        
    sRange.TextFrame2.AutoSize = msoAutoSizeShapeToFitText
        
    sRange(1).TextFrame2.TextRange.Text = "This is a test. It's only a test."
    sRange(2).TextFrame2.TextRange.Text = "This is text box 2."
    sRange(1).TextFrame2.TextRange.Characters.Font.Fill.ForeColor.RGB = &H2020CC
    sRange.Fill.ForeColor.RGB = &H88CCCC
        
    With sRange.TextEffect
        .FontName = "Courier New"
        .FontBold = True
        .FontItalic = True
        .FontSize = 28
    End With
    
    sRange(2).Select
End Sub

Valor de propriedade

TEXTFRAME2

Confira também

Shape ObjectTextFrame2

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.