Configuração típica de projetos Lakebase com Terraform

Importante

O suporte ao Terraform para o Lakebase está em Beta.

Esta página mostra uma configuração completa do Terraform para um projeto Lakebase pronto para produção com as funcionalidades mais usadas:

  • Ramo de produção protegido
  • Endpoint de leitura-escrita de alta disponibilidade (HA) com secundários legíveis
  • Nome principal de serviço com privilégios na DATABRICKS_SUPERUSER base de dados
  • Base de dados Postgres, propriedade da aplicação
  • Base de dados Postgres registada no Catálogo Unity para consultas da Federação Lakehouse a partir do Databricks, SQL e notebooks
  • Tabela sincronizada em transmissão contínua do Unity Catalog
  • Aplicação Databricks ligada ao projeto Lakebase

Para uma introdução passo a passo ao Terraform com Lakebase, consulte Comece com Terraform para Lakebase.

Pré-requisitos

Antes de começar, você deve ter o seguinte:

Configuração completa

Quando cria um projeto, o Azure Databricks cria automaticamente um ramo production, um ponto final primary de leitura e escrita, uma função de proprietário do Postgres associada à sua identidade e uma base de dados databricks_postgres. Para configurar estes recursos implícitamente criados, declare-os no Terraform com replace_existing = true. Para mais detalhes, veja databricks_postgres_branch, databricks_postgres_endpoint, databricks_postgres_role, e databricks_postgres_database.

Advertência

Esta configuração define is_protected = true no ramo production e inclui uma variável unprotect_for_destroy integrada na especificação do ramo. O Terraform não pode eliminar um projeto que contenha ramos protegidos, e o production ramo não pode ser eliminado diretamente porque o seu ciclo de vida é controlado pelo projeto. Para destruir recursos de forma limpa, use uma destruição em dois passos:

# Step 1: unprotect the branch
terraform apply -var="unprotect_for_destroy=true"

# Step 2: destroy all resources
terraform destroy -var="unprotect_for_destroy=true"

Após a execução terraform destroy, o projeto é apagado de forma suave e mantido durante 7 dias antes de ser eliminado permanentemente. Para o eliminar permanentemente de imediato, defina purge_on_delete = true no recurso databricks_postgres_project antes de executar destroy.

variable "admin_sp_app_id" {
  description = "Application ID of the service principal to grant admin access"
  type        = string
}

variable "unprotect_for_destroy" {
  description = "Set to true before destroy to unprotect the production branch"
  type        = bool
  default     = false
}

# Project — top-level container for branches, endpoints, databases, and roles.
resource "databricks_postgres_project" "this" {
  project_id = "my-lakebase-project"
  # purge_on_delete = true  # Uncomment to permanently delete on destroy (default: soft delete, 7-day retention).
  spec = {
    pg_version   = 17
    display_name = "My Lakebase Project"
    default_endpoint_settings = {
      autoscaling_limit_min_cu = 0.5
      autoscaling_limit_max_cu = 4.0
      suspend_timeout_duration = "300s"
    }
  }
}

# Configure the implicitly created production branch as protected.
resource "databricks_postgres_branch" "production" {
  branch_id = "production"
  parent    = databricks_postgres_project.this.name
  spec = {
    no_expiry    = true
    is_protected = var.unprotect_for_destroy ? false : true
  }
  replace_existing = true
}

# Configure the implicitly created primary endpoint with HA.
# HA requires no_suspension = true. group.min = 2 adds a standby for automatic failover.
resource "databricks_postgres_endpoint" "primary" {
  endpoint_id = "primary"
  parent      = databricks_postgres_branch.production.name
  spec = {
    endpoint_type            = "ENDPOINT_TYPE_READ_WRITE"
    autoscaling_limit_min_cu = 0.5
    autoscaling_limit_max_cu = 4.0
    no_suspension            = true
    group = {
      min                         = 2
      max                         = 2
      enable_readable_secondaries = true
    }
  }
  replace_existing = true
}

# Grant workspace-level CAN_MANAGE on the project to the service principal.
# Use status.project_id (bare ID) not .name (full resource path) — the permissions
# API rejects the full path with a "resource type not found" error.
resource "databricks_permissions" "project" {
  database_project_name = databricks_postgres_project.this.status.project_id
  access_control {
    service_principal_name = var.admin_sp_app_id
    permission_level       = "CAN_MANAGE"
  }
}

# Create a Postgres role backed by the service principal with full database privileges.
# depends_on serializes creation — Lakebase processes one branch operation at a time.
resource "databricks_postgres_role" "admin_sp" {
  role_id = "admin-sp"
  parent  = databricks_postgres_branch.production.name
  spec = {
    identity_type    = "SERVICE_PRINCIPAL"
    postgres_role    = var.admin_sp_app_id
    auth_method      = "LAKEBASE_OAUTH_V1"
    membership_roles = ["DATABRICKS_SUPERUSER"]
    attributes = {
      createdb   = true
      createrole = true
      bypassrls  = true
    }
  }
  depends_on = [databricks_postgres_endpoint.primary]
}

# Create a Postgres database owned by the admin SP role.
resource "databricks_postgres_database" "app" {
  database_id = "app"
  parent      = databricks_postgres_branch.production.name
  spec = {
    postgres_database = "app"
    role              = databricks_postgres_role.admin_sp.name
  }
}

# Register the Postgres database in Unity Catalog. This makes the database queryable
# from Databricks SQL and notebooks through Lakehouse Federation, and serves as the
# parent namespace for synced tables that live inside the Lakebase Catalog.
# create_database_if_missing is set explicitly because the database is managed by
# the databricks_postgres_database resource above.
resource "databricks_postgres_catalog" "app_catalog" {
  catalog_id = "app_catalog"
  spec = {
    postgres_database          = databricks_postgres_database.app.status.postgres_database
    branch                     = databricks_postgres_branch.production.name
    create_database_if_missing = false
  }
}

# Sync a Unity Catalog Delta table into the Lakebase database continuously.
# Prefixing synced_table_id with the Lakebase Catalog name places the synced table
# inside the catalog so it's discoverable alongside the rest of the catalog's contents.
# postgres_database references the catalog's status, which implicitly orders this
# resource after the catalog without an explicit depends_on.
resource "databricks_postgres_synced_table" "orders" {
  synced_table_id = "app_catalog.default.orders_synced"
  spec = {
    branch                             = databricks_postgres_branch.production.name
    postgres_database                  = databricks_postgres_catalog.app_catalog.status.postgres_database
    source_table_full_name             = "my_catalog.default.orders"
    primary_key_columns                = ["order_id"]
    scheduling_policy                  = "CONTINUOUS"
    create_database_objects_if_missing = true
    new_pipeline_spec = {
      storage_catalog = "my_catalog"
      storage_schema  = "default"
    }
  }
}

# Databricks App connected to the Lakebase project.
# database must be the full resource name (databricks_postgres_database.app.name),
# not the Postgres database name. permission must be "CAN_CONNECT_AND_CREATE".
resource "databricks_app" "this" {
  name        = "my-lakebase-app"
  description = "App backed by Lakebase autoscaling project"
  depends_on  = [databricks_postgres_database.app]
  resources = [{
    name = "lakebase-db"
    postgres = {
      branch     = databricks_postgres_branch.production.name
      database   = databricks_postgres_database.app.name
      permission = "CAN_CONNECT_AND_CREATE"
    }
  }]
}

Observação

Esta configuração cria uma função separada (admin_sp) e uma base de dados (app) em vez de gerir a função implícita de proprietário e a base de dados databricks_postgres. Para que esses recursos implícitos passem a ser geridos pelo Terraform, declare-os com replace_existing = true utilizando os respetivos IDs existentes. O ID da base de dados é sempre databricks-postgres. O ID da função é derivado da identidade que criou a ramificação: a parte do endereço de e-mail antes de @ (convertida em minúsculas, com os caracteres não alfanuméricos substituídos por hífenes) para um utilizador, ou sp-<application-id> para uma entidade de serviço. Se não tiveres a certeza do valor exato, lê-o na aplicação Lakebase ou na API Postgres em vez de o derivar manualmente.

spec.membership_roles Sobrescreve as inscrições da função em cada candidatura em vez de se fundir com elas. Mantenha DATABRICKS_SUPERUSER na lista; deixá-la de fora remove todas as associações da função.

resource "databricks_postgres_role" "owner" {
  role_id = "jane-doe" # normalized login of the creating identity
  parent  = databricks_postgres_branch.production.name
  spec = {
    postgres_role    = "jane.doe@databricks.com" # the raw login
    membership_roles = ["DATABRICKS_SUPERUSER"]
    attributes = {
      createdb   = true
      createrole = true
      bypassrls  = true
    }
  }
  replace_existing = true
}

resource "databricks_postgres_database" "databricks_postgres" {
  database_id = "databricks-postgres"
  parent      = databricks_postgres_branch.production.name
  spec = {
    postgres_database = "databricks_postgres"
    # spec.role is omitted, so the database keeps its existing owner.
  }
  replace_existing = true
}

Recursos adicionais

  • Last updated on