Guia de início rápido: criar uma instância do Banco de Dados do Azure para MySQL - Servidor flexível usando o Terraform

Este guia de início rápido foi testado com recurso às seguintes versões do Terraform e do fornecedor do Terraform:

• Terraforma v1.2.7
• AzureRM Provider v.3.20.0

O Banco de Dados do Azure para MySQL - Servidor Flexível é um serviço gerenciado que você usa para executar, gerenciar e dimensionar bancos de dados MySQL altamente disponíveis na nuvem. Você pode usar um modelo do Azure Resource Manager (modelo ARM) para provisionar o Banco de Dados do Azure para MySQL - Servidor Flexível para implantar vários servidores ou implantar vários bancos de dados em um servidor.

Este artigo mostra como usar o Terraform para implantar uma instância do Banco de Dados do Azure para MySQL - Servidor Flexível e um banco de dados em uma rede virtual.

Neste artigo, vai aprender a:

Pré-requisitos

• Se você não tiver uma assinatura do Azure, crie uma conta gratuita do Azure antes de começar. Atualmente, com uma conta gratuita do Azure, você pode experimentar o Banco de Dados do Azure para MySQL - Servidor Flexível gratuitamente por 12 meses. Para obter mais informações, consulte Usar uma conta gratuita do Azure para experimentar o Banco de Dados do Azure para MySQL - Servidor Flexível gratuitamente.

• Instalar e configurar o Terraform

Implementar o código Terraform

1. Crie um diretório que você pode usar para testar o código Terraform de exemplo. Faça do diretório Terraform o diretório atual.

2. Crie um arquivo chamado providers.tf e insira o seguinte código:

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
   
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Crie um arquivo chamado main.tf e insira o seguinte código:

   # Generate random resource group name
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   # Generate random value for the name
   resource "random_string" "name" {
     length  = 8
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   # Generate random value for the login password
   resource "random_password" "password" {
     length           = 8
     lower            = true
     min_lower        = 1
     min_numeric      = 1
     min_special      = 1
     min_upper        = 1
     numeric          = true
     override_special = "_"
     special          = true
     upper            = true
   }
   
   # Manages the Virtual Network
   resource "azurerm_virtual_network" "default" {
     address_space       = ["10.0.0.0/16"]
     location            = azurerm_resource_group.rg.location
     name                = "vnet-${random_string.name.result}"
     resource_group_name = azurerm_resource_group.rg.name
   }
   
   # Manages the Subnet
   resource "azurerm_subnet" "default" {
     address_prefixes     = ["10.0.2.0/24"]
     name                 = "subnet-${random_string.name.result}"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.default.name
     service_endpoints    = ["Microsoft.Storage"]
   
     delegation {
       name = "fs"
   
       service_delegation {
         name = "Microsoft.DBforMySQL/flexibleServers"
         actions = [
           "Microsoft.Network/virtualNetworks/subnets/join/action",
         ]
       }
     }
   }
   
   # Enables you to manage Private DNS zones within Azure DNS
   resource "azurerm_private_dns_zone" "default" {
     name                = "${random_string.name.result}.mysql.database.azure.com"
     resource_group_name = azurerm_resource_group.rg.name
   }
   
   # Enables you to manage Private DNS zone Virtual Network Links
   resource "azurerm_private_dns_zone_virtual_network_link" "default" {
     name                  = "mysqlfsVnetZone${random_string.name.result}.com"
     private_dns_zone_name = azurerm_private_dns_zone.default.name
     resource_group_name   = azurerm_resource_group.rg.name
     virtual_network_id    = azurerm_virtual_network.default.id
   
     depends_on = [azurerm_subnet.default]
   }
   
   # Manages the MySQL Flexible Server
   resource "azurerm_mysql_flexible_server" "default" {
     location                     = azurerm_resource_group.rg.location
     name                         = "mysqlfs-${random_string.name.result}"
     resource_group_name          = azurerm_resource_group.rg.name
     administrator_login          = random_string.name.result
     administrator_password       = random_password.password.result
     backup_retention_days        = 7
     delegated_subnet_id          = azurerm_subnet.default.id
     geo_redundant_backup_enabled = false
     private_dns_zone_id          = azurerm_private_dns_zone.default.id
     sku_name                     = "GP_Standard_D2ds_v4"
     version                      = "8.0.21"
   
     high_availability {
       mode                      = "SameZone"
     }
     maintenance_window {
       day_of_week  = 0
       start_hour   = 8
       start_minute = 0
     }
     storage {
       iops    = 360
       size_gb = 20
     }
   
     depends_on = [azurerm_private_dns_zone_virtual_network_link.default]
   }
   

4. Crie um arquivo chamado mysql-fs-db.tf e insira o seguinte código:

   # Manages the MySQL Flexible Server Database
   resource "azurerm_mysql_flexible_database" "main" {
     charset             = "utf8mb4"
     collation           = "utf8mb4_unicode_ci"
     name                = "mysqlfsdb_${random_string.name.result}"
     resource_group_name = azurerm_resource_group.rg.name
     server_name         = azurerm_mysql_flexible_server.default.name
   }
   

5. Crie um arquivo chamado variables.tf e insira o seguinte código:

   variable "resource_group_location" {
     type        = string
     default     = "westeurope"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "mysql-fs-db-rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

6. Crie um arquivo chamado outputs.tf e insira o seguinte código:

   output "azurerm_mysql_flexible_server" {
     value = azurerm_mysql_flexible_server.default.name
   }
   
   output "admin_login" {
     value = azurerm_mysql_flexible_server.default.administrator_login
   }
   
   output "admin_password" {
     sensitive = true
     value     = azurerm_mysql_flexible_server.default.administrator_password
   }
   
   output "mysql_flexible_server_database_name" {
     value = azurerm_mysql_flexible_database.main.name
   }
   
   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   

Inicializar o Terraform

Execute terraform init para inicializar a implantação do Terraform. Este comando baixa o provedor do Azure necessário para gerenciar seus recursos do Azure.

terraform init -upgrade

Pontos principais:

• O -upgrade parâmetro atualiza os plug-ins de provedor necessários para a versão mais recente que está em conformidade com as restrições de versão da configuração.

Criar um plano de execução do Terraform

Execute terraform plan para criar um plano de execução.

terraform plan -out main.tfplan

Pontos principais:

• O terraform plan comando cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
• O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

Aplicar um plano de execução do Terraform

Execute terraform apply para aplicar o plano de execução à sua infraestrutura de nuvem.

terraform apply main.tfplan

Pontos principais:

• O comando de exemplo terraform apply pressupõe que executou anteriormente terraform plan -out main.tfplan.
• Se você especificou um nome de arquivo diferente para o -out parâmetro, use esse mesmo nome de arquivo na chamada para terraform apply.
• Se você não usou o -out parâmetro, ligue terraform apply sem nenhum parâmetro.

Verificar os resultados

az mysql flexible-server db show \
    --resource-group <resource_group_name> \
    --server-name <azurerm_mysql_flexible_server> \
    --database-name <mysql_flexible_server_database_name>

Get-AzMySqlFlexibleServerDatabase `
    -ResourceGroupName <resource_group_name> `
    -ServerName <azurerm_mysql_flexible_server> `
    -Name <mysql_flexible_server_database_name>

Limpar recursos

Quando você não precisar mais dos recursos criados via Terraform, execute as seguintes etapas:

1. Execute terraform plan e especifique a opção destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Pontos principais:

   • O terraform plan comando cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
   • O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

2. Execute terraform apply para aplicar o plano de execução.

   terraform apply main.destroy.tfplan
   

Solucionar problemas do Terraform no Azure

Explore como solucionar problemas comuns de uso do Terraform no Azure.

Próximo passo