dax_request plugin

O dax_request plugin executa uma consulta de Expressões de Análise de Dados (DAX) contra um modelo semântico do Power BI e devolve os resultados como uma tabela. Processe a tabela devolvida com operadores padrão da Linguagem de Consulta Kusto (KQL). Invocar o plugin com o operador avaliar.

O plugin utiliza a API Power BI Execute DAX Queries, que devolve resultados em formato Apache Arrow. O plugin preserva os tipos de coluna suportados quando converte a resposta para uma tabela KQL.

Note

O dax_request plugin está em pré-visualização.

Prerequisites

  • O modelo semântico deve estar num espaço de trabalho atribuído a uma capacidade Fabric ou Power BI Premium.
  • A API REST do Dataset Execute Queries, Permitir endpoints XMLA e Analisar no Excel com modelos semânticos locais devem estar ativadas.
  • Deve ter permissões de Build e Read no modelo semântico.
  • A política de chamadas de cluster deve permitir dax chamadas a api.powerbi.com. Para alterar esta política, precisa AllDatabasesAdmin de permissões Ops .

Sintaxe

evaluate dax_request ( ConnectionString,DaxQuery) [:OutputSchema]

Saiba mais sobre convenções sintáticas nas convenções sintáticas para documentação de referência.

Parameters

Nome Tipo Obrigatória Description
ConnectionString string Yes A URL do modelo semântico seguida de ;Impersonate. Para os formatos URL suportados, veja String de Ligação.
DaxQuery string Yes A consulta DAX para ser executada contra o modelo semântico.
OutputSchema - - Os nomes e tipos das colunas de saída esperadas. Use a sintaxe (ColumnName:ColumnType [, ...].)

Note

Recomenda-se especificar o OutputSchema . Permite ao Kusto determinar as colunas e tipos de saída do plugin sem enviar a consulta DAX para o Power BI durante a descoberta do esquema. O pedido do Power BI é, em vez disso, adiado para a execução da consulta, juntamente com o resto da consulta KQL. O plugin devolve um erro se o esquema devolvido for incompatível com o esquema declarado.

Cadeia de ligação

A cadeia de ligação consiste na URL do modelo semântico e na ;Impersonate diretiva de autenticação. Use um dos seguintes formatos:

  • Modelo semântico num espaço de trabalho: https://api.powerbi.com/v1.0/myorg/groups/WorkspaceId/datasets/SemanticModelId;Impersonate

  • Modelo semântico no meu espaço de trabalho: https://api.powerbi.com/v1.0/myorg/datasets/SemanticModelId;Impersonate

O myorg segmento do caminho é literal. *WorkspaceId* e *SemanticModelId* devem ser identificadores globalmente únicos (GUIDs). Não incluas uma cadeia de consulta, fragmento ou caminho final depois do SemanticModelId.

Autenticação e autorização

O plugin utiliza o Microsoft Entra em nome da autenticação. O motor obtém um token para o utilizador solicitante e envia a consulta DAX no contexto de segurança desse utilizador. O utilizador deve ter permissões de Construção e Leitura no modelo semântico. Qualquer segurança ao nível da linha ou ao nível do objeto configurada para o utilizador aplica-se à consulta.

Use ;Impersonate como diretiva de autenticação. Identidade gerida, principal de serviço e autenticação por chave de aplicação não são suportados.

Importante

Use um literal de cadeia ofuscada para qualquer cadeia que contenha informação confidencial. Valores ofuscados não aparecem no rastreamento Kusto.

Configurar e chamar política

O plugin faz uma chamada externa para o Power BI. Como a política de callout por defeito bloqueia dax callouts, um administrador do cluster deve permitir explicitamente o endpoint do Power BI.

O comando seguinte funde uma regra restritiva dax na política existente de chamadas do cluster:

.alter-merge cluster policy callout @'[{
  "CalloutType": "dax",
  "CalloutUriRegex": "api\\.powerbi\\.com.*",
  "CanCall": true
}]'

Verifique a apólice:

.show cluster policy callout

Returns

O plugin devolve o resultado da consulta DAX como uma tabela KQL. Preserva os tipos de dados Arrow suportados. Por exemplo, a seta int64, double, utf8, e date-time os valores mapeiam para Kusto long, real, string, e datetime, respetivamente.

O Power BI devolve nomes de colunas entre parênteses, como [Category]. Em KQL, referencia-se estes nomes com a ['...'] sintaxe, como ['[Category]'].

Warning

O plugin utiliza o limite de linhas predefinido da API Power BI Execute DAX Queries (resultSetRowCountLimit). Se a consulta DAX produzir mais linhas do que este limite, a tabela devolvida pode ficar incompleta sem erro. Filtre ou agregue dados na consulta DAX para manter o resultado dentro do limite. Filtrar ou agregar depois no KQL não recupera linhas omitidas.

Examples

Devolver todas as linhas de uma tabela

O exemplo seguinte interroga a Sales tabela. O resultado devolvido está sujeito ao limite de linhas padrão da API.

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE Sales')

Resultados do DAX processado com Kusto

O exemplo seguinte seleciona duas colunas em DAX, resume o resultado em KQL e filtra por categoria:

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE SELECTCOLUMNS(Sales, "Category", Sales[Category], "Amount", Sales[Amount])')
| summarize TotalAmount = sum(['[Amount]']) by ['[Category]']
| where ['[Category]'] == 'Electronics'

Dica

Filtrar e agregar dados no DAX sempre que possível para reduzir a quantidade de dados devolvidos ao Kusto.

Especificar um esquema de saída

O exemplo seguinte declara o esquema de saída esperado para que o Kusto possa determinar o esquema sem contactar o Power BI durante a análise da consulta. O esquema declarado deve corresponder ao esquema de resultados em tempo real.

evaluate dax_request(
  'https://api.powerbi.com/v1.0/myorg/groups/<workspace-id>/datasets/<semantic-model-id>;Impersonate',
  'EVALUATE ROW("cnt", COUNTROWS(Sales), "sumAmt", SUM(Sales[Amount]))')
  : (['[cnt]']:long, ['[sumAmt]']:real)

Troubleshooting

Error Causa e resolução
cadeia de ligação inválida Confirme que a URL usa um formato suportado, que os IDs do workspace e do modelo semântico são GUIDs válidos, e que a cadeia termina em ;Impersonate.
Não é permitido o chamado Configure a política de callout do cluster para permitir dax chamadas para api.powerbi.com.
Erro de autenticação ou autorização Confirme que as definições de inquilino exigidas estão ativadas e que o utilizador solicitante tem permissão de Construção e Leitura no modelo semântico.
Erro de pedido HTTP Garantir a disponibilidade do serviço Power BI, acessibilidade ao endpoint e a URL semântica do modelo.