Método Views.Add (Outlook)

Cria um novo modo de exibição no conjunto Views.

Sintaxe

mais simples. Adicionar (Name, ViewType, SaveOption)

expressão Uma variável que representa um objeto Views .

Parâmetros

Nome Obrigatório/Opcional Tipo de dados Descrição
Name Obrigatório String O nome do novo modo de exibição.
ViewType Obrigatório OlViewType O tipo do novo modo de exibição.
SaveOption Opcional OlViewSaveOption A opção salvar que especifica as permissões do novo modo de exibição:
  • olViewSaveOptionAllFoldersOfType O modo de exibição pode ser acessado em todas as pastas desse tipo.
  • olViewSaveOptionThisFolderEveryOne O modo de exibição pode ser acessado por todos os usuários somente nesta pasta.
  • olViewSaveOptionThisFolderOnlyMe O modo de exibição pode ser acessado nesta pasta somente pelo usuário.

Valor de retorno

Um objeto View que representa o novo modo de exibição.

Comentários

Se você adicionar um Modo de Exibição a uma coleção de Modos de Exibição de uma pasta que não seja a pasta atual, primeiro salve uma cópia do objeto de coleção Modos de Exibição e, em seguida, adicione o Modo de Exibição a esse objeto de coleção, conforme mostrado no exemplo de código a seguir. Essa é uma solução alternativa para um problema existente que, de outra forma, fará com que uma chamada para View.Apply para a exibição adicionada falhe.

Sub CalendarView() 
 Dim calView As Outlook.View 
 Dim vws As Views 
 
 Set Application.ActiveExplorer.CurrentFolder = Application.Session.GetDefaultFolder(olFolderInbox) 
 ' Current folder is Inbox; add a View to the Calendar folder which is not the current folder 
 ' Keep a copy of the object for the Views collection for the Calendar 
 Set vws = Application.Session.GetDefaultFolder(olFolderCalendar).Views 
 ' Add the View to this Views collection object 
 Set calView = vws.Add("New Calendar", olCalendarView, olViewSaveOptionThisFolderEveryone) 
 calView.Save 
 ' This Apply call will be fine 
 calView.Apply 
End Sub

Exemplo

O seguinte exemplo do Visual Basic for Applications (VBA) cria uma nova exibição chamada Nova Tabela e a armazena em uma variável chamada objNewView.

Sub CreateView() 
 'Creates a new view 
 Dim objName As Outlook.NameSpace 
 Dim objViews As Outlook.Views 
 Dim objNewView As Outlook.View 
 
 Set objName = Application.GetNamespace("MAPI") 
 Set objViews = objName.GetDefaultFolder(olFolderInbox).Views 
 Set objNewView = objViews.Add(Name:="New Table", _ 
 ViewType:=olTableView, SaveOption:=olViewSaveOptionThisFolderEveryone) 
End Sub

Suporte e comentários

Tem dúvidas ou quer enviar comentários sobre o VBA para Office ou sobre esta documentação? Confira Suporte e comentários sobre o VBA para Office a fim de obter orientação sobre as maneiras pelas quais você pode receber suporte e fornecer comentários.

  • Last updated on