SharePoint.Contents

Sintaxe

SharePoint.Contents(url as text, optional options as nullable record) as table

Sobre nós

Devolve uma tabela hierárquica contendo as pastas e ficheiros encontrados no site SharePoint especificado, url. A tabela mostra os itens ao nível atual e não devolve recursivamente todos os ficheiros do site. Para pastas, a Content coluna contém uma tabela aninhada que pode ser usada para navegar até ao conteúdo da pasta. Para ficheiros, a Content coluna contém o conteúdo do ficheiro como um valor binário. Para devolver uma tabela plana de todos os ficheiros no site e nas suas subpastas, use SharePoint.Files. Cada linha também contém as Name, Extension, Date accessed, Date modified, Date created, Attributes, e Folder Path colunas. As linhas das pastas têm um valor vazio Extension . Date accessed é null para pastas e ficheiros. O Folder Path valor é o URL absoluto da pasta que contém o item. O URL do site não pode conter uma string de consulta ou fragmento. options pode ser especificado para controlar as seguintes opções:

  • ApiVersion: Um número (14 ou 15) ou o texto "Auto" que especifica a versão da API do SharePoint a ser usada para este site. Quando não especificado, a API versão 14 é usada. Quando Auto é especificado, a versão do servidor será descoberta automaticamente, se possível, caso contrário, a versão padrão é 14. Sites do SharePoint que não estejam em inglês exigem pelo menos a versão 15.
  • Implementation: Opcional. Especifica qual versão do conector do SharePoint usar. Os valores aceites são "2.0" ou null. Se o valor for "2.0", a implementação 2.0 do conector do SharePoint será usada. Se o valor for null, a implementação original do conector do SharePoint será usada.

Para SharePoint.Contents, a implementação original suporta ApiVersion os valores 14, 15 e "Auto". Se ApiVersion não for especificado, é usada a versão 14. Com a implementação 2.0, ApiVersion não é necessário especificar porque a versão 15 da API é usada automaticamente. A versão 14 da API não é suportada com a implementação 2.0.

Exemplo 1

Devolve o conteúdo de topo do SharePoint usando a implementação original. Como não são especificadas opções, utiliza-se a versão 14 da API.

Usage

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Output

A hierarchical table containing the top-level folders and files in the site.

Exemplo 2

Use a implementação original com seleção automática de API para devolver todos os .xlsx ficheiros na biblioteca de Documentos Partilhados. A comparação das extensões é indistinta a maiúsculas minúsculas.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Output

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Exemplo 3

Use a implementação 2.0 para devolver o conteúdo imediato da pasta Relatórios na biblioteca de Documentos Partilhados. A implementação 2.0 utiliza a versão 15 da API por defeito.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Output

A hierarchical table containing the immediate folders and files in the Reports folder.

Exemplo 4

Devolva o conteúdo binário de Budget.xlsx navegando pelos conteúdos hierárquicos do site.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Output

The binary content of Budget.xlsx.

  • Última atualização a