Skapa formkartevisualiseringar i Power BI

Gäller för:✅ Power BI Desktop och služba Power BI

Använd ett visuellt formöversiktsobjekt för att visa data på alla former som du kan definiera – länder, regioner, planritningar, sittdiagram eller anpassade gränser. Färga varje område baserat på dina data för att snabbt upptäcka mönster, jämföra värden mellan regioner och markera områden som behöver uppmärksamhet. Välj bland inbyggda kartor för vanliga regioner, ladda upp egna TopoJSON- eller GeoJSON-filer eller referenskartor direkt via URL.

Skapa en formkarta

Du kan testa kontrollen Formkarta med de inbyggda kartorna, eller så kan du använda din egen anpassade karta så länge den uppfyller kraven som beskrivs i följande avsnitt med namnet Använd anpassade kartor. Visuella formkartor baseras på kartor som du kan hitta på Internet, skapa dig själv eller konvertera till TopoJSON- eller GeoJSON-format. Exempel på anpassade kartor är: geografiska platser, sittplatser, planritningar och andra.

Lägga till ett visuellt formöversiktsobjekt

1. Öppna eller skapa en rapport i Power BI Desktop eller služba Power BI.
2. I fönstret Visualiseringar väljer du ikonen Formkarta för att lägga till ett tomt visuellt objekt på arbetsytan.
3. (Valfritt) Ändra storlek på det visuella objektet så att det är tillräckligt stort för att visa regionskuggning tydligt.

Exempeldata för testning

Om du vill prova det visuella objektet Formkarta med exempeldata kan du lägga till det här TMDL-skriptet i en tom Power BI Desktop-fil. Det här skriptet skapar en tabell med amerikanska delstater och australiska delstater och territorier, tillsammans med slumpmässiga värden i demonstrationssyfte.

createOrReplace

	/// Table listing US states and Australian states and territories with random values, used for map visual demos.
	table Map

		/// Sum of RandomValue from the Map table, used for the map visual demo.
		measure 'Some value' = ```
				
				        SUM(Map[RandomValue])
				```
			formatString: #,0

		column RandomValue
			formatString: 0
			summarizeBy: sum
			isNameInferred
			sourceColumn: [RandomValue]

			annotation SummarizationSetBy = Automatic

		column 'Country or Region'
			dataCategory: Country
			summarizeBy: none
			isNameInferred
			sourceColumn: [Country or Region]

			annotation SummarizationSetBy = Automatic

		column 'State or Territory'
			dataCategory: StateOrProvince
			summarizeBy: none
			isNameInferred
			sourceColumn: [State or Territory]

			annotation SummarizationSetBy = Automatic

		partition Map = calculated
			mode: import
			source = ```
					
					VAR USAStates = 
					    DATATABLE(
					        "Country or Region", STRING,
					        "State or Territory", STRING,
					        {
					            {"USA", "Alabama"},
					            {"USA", "Alaska"},
					            {"USA", "Arizona"},
					            {"USA", "Arkansas"},
					            {"USA", "California"},
					            {"USA", "Colorado"},
					            {"USA", "Connecticut"},
					            {"USA", "Delaware"},
					            {"USA", "Florida"},
					            {"USA", "Georgia"},
					            {"USA", "Hawaii"},
					            {"USA", "Idaho"},
					            {"USA", "Illinois"},
					            {"USA", "Indiana"},
					            {"USA", "Iowa"},
					            {"USA", "Kansas"},
					            {"USA", "Kentucky"},
					            {"USA", "Louisiana"},
					            {"USA", "Maine"},
					            {"USA", "Maryland"},
					            {"USA", "Massachusetts"},
					            {"USA", "Michigan"},
					            {"USA", "Minnesota"},
					            {"USA", "Mississippi"},
					            {"USA", "Missouri"},
					            {"USA", "Montana"},
					            {"USA", "Nebraska"},
					            {"USA", "Nevada"},
					            {"USA", "New Hampshire"},
					            {"USA", "New Jersey"},
					            {"USA", "New Mexico"},
					            {"USA", "New York"},
					            {"USA", "North Carolina"},
					            {"USA", "North Dakota"},
					            {"USA", "Ohio"},
					            {"USA", "Oklahoma"},
					            {"USA", "Oregon"},
					            {"USA", "Pennsylvania"},
					            {"USA", "Rhode Island"},
					            {"USA", "South Carolina"},
					            {"USA", "South Dakota"},
					            {"USA", "Tennessee"},
					            {"USA", "Texas"},
					            {"USA", "Utah"},
					            {"USA", "Vermont"},
					            {"USA", "Virginia"},
					            {"USA", "Washington"},
					            {"USA", "West Virginia"},
					            {"USA", "Wisconsin"},
					            {"USA", "Wyoming"}
					        }
					    )
					VAR AustraliaStates = 
					    DATATABLE(
					        "Country", STRING,
					        "State", STRING,
					        {
					            {"Australia", "New South Wales"},
					            {"Australia", "Victoria"},
					            {"Australia", "Queensland"},
					            {"Australia", "Western Australia"},
					            {"Australia", "South Australia"},
					            {"Australia", "Tasmania"},
					            {"Australia", "Northern Territory"},
					            {"Australia", "Australian Capital Territory"}
					        }
					    )
					VAR AllStates = UNION(USAStates, AustraliaStates)
					RETURN
					    ADDCOLUMNS(
					        AllStates,
					        "RandomValue", RANDBETWEEN(1000, 1000000)
					    )
					```

Skapa formkartan

1. Välj det tomma Shape map-diagrammet.

2. I rutan Data drar du ett geografiskt fält till området Plats (till exempel delstat, region eller distrikt).

   Tip

   Du kan markera en kolumn som geografisk genom att ange egenskapen Datakategori när du redigerar den semantiska modellen.

3. Dra ett numeriskt mått (till exempel Försäljning, Befolkning) till färgmättnad.

4. När det visuella objektet fortfarande är markerat går du till fönstret Visualiseringar och väljer Formatera visuellt objekt och expanderar Kartinställningar.

5. Välj en karttyp (till exempel Italien, Mexiko, USA) i listrutan.

6. Om du vill visa kartnycklarna för den markerade kartan väljer du Visa karttypnyckel.

7. Välj vilket sätt du vill visa ett tredimensionellt objekt (jorden) som en tvådimensionell karta med hjälp av listrutan Projektion .

   • Equirectangular: Cylindrisk projektion som omvandlar världen till ett rutnät där varje rektangulär cell har samma storlek, form och yta.
   • Mercator: Cylindrisk projektion med ekvatorn avbildad som tangenslinjen. Polära områden är mer förvrängda än Equirectangular-projektioner.
   • Ortogonala projektioner: En projektion från en oändlig punkt, som från djuprymden. Det ger illusionen av en tredimensionell jordglob.

   Mer detaljerad information finns i referensen för Esri-kartprojektioner.

8. (Valfritt) Lägg till ett kategoriskt fält i Förklaring för att klassificera kartregionerna efter kategori.

9. (Valfritt) I fönstret Visualiseringar expanderar du Färger för att justera paletten och andra färginställningar.

Använda anpassade kartor

Du kan använda de inbyggda karttyperna eller din egen anpassade karta så länge den uppfyller kraven som beskrivs i Läs in en anpassad karta. Visuella formkartor baseras på kartor som du kan hitta, skapa eller konvertera till TopoJSON- eller GeoJSON-format (till exempel geografiska regioner, placeringslayouter, planritningar).

Läs in en anpassad karta

Du kan läsa in en anpassad karta genom att ladda upp en fil eller ange en URL.

Ladda upp en kartfil

1. Lägg till eller välj ett visuellt formöversiktsobjekt.
2. I fönstret Visualiseringar väljer du Formatera visuellt objekt och expanderar Kartinställningar.
3. I Karttyp väljer du Anpassad karta.
4. Välj Lägg till en karttyp.
5. Bläddra till och välj filen .topojson eller .geojson och välj sedan Öppna.
6. (Valfritt) Välj Visa mappningstypnyckel för att kontrollera att regionnamnen eller ID:na matchar dina platsfältvärden .

Lägga till en karta från URL

Du kan också referera till en kartfil som finns online:

1. Lägg till eller välj ett visuellt formöversiktsobjekt.
2. I fönstret Visualiseringar väljer du Formatera visuellt objekt och expanderar Kartinställningar.
3. I Typ väljer du URL.
4. Klistra in URL:en till en TopoJSON- eller GeoJSON-fil i Ange en URL, eller använd knappen Fx för att peka på ett mått som innehåller URL:en.

Den här metoden är användbar när du vill dela en karta över flera rapporter eller använda en karta som finns på en central plats.

Ladda ned och redigera en anpassad karta

Om du tidigare har laddat upp en anpassad karta och behöver göra ändringar kan du ladda ned den:

1. Välj det visuella Shape map-objektet som använder den anpassade kartan.
2. Öppna fönstret Format och expandera Kartinställningar.
3. Välj Ladda ned karta.
4. Redigera den nedladdade filen efter behov med hjälp av en textredigerare eller ett GIS-verktyg.
5. Ladda upp den uppdaterade filen med hjälp av stegen i Ladda upp en kartfil.

Exempel på anpassad karta

Kontoren för USA:s federala åklagare publicerar årligen en rapport för räkenskapsåret om data kring rättstvister och ärendemängd. Vi konverterar en del av deras distriktsdata till .json filer och lägger till dem i det här PBIX-exemplet.

Demo för anpassad formkarta . PBIX-fil

Om du vill experimentera med anpassade kartor laddar du ned den här PBIX-filen och följer med.

1. Från Power BI Desktop väljer du Öppna filrapport>.
2. Eftersom delstater kan delas in i flera distrikt måste du använda en anpassad formkarta för distrikt. Genom att importera TopoJSON-kartan över de amerikanska rättsdistrikten till Power BI Desktop kan du visualisera de årliga skatteåklagarens data.

Kartformat som stöds

Formkarta stöder två kartfilformat:

• TopoJSON: Ett tillägg av GeoJSON som kodar topologi. TopoJSON-filer är vanligtvis mindre än GeoJSON-filer eftersom delade gränser bara lagras en gång.
• GeoJSON: Ett öppet standardformat för kodning av geografiska datastrukturer.

Båda formaten fungerar med Shape map. Använd TopoJSON för mindre filstorlekar eller GeoJSON om det är vad dina kartverktyg producerar.

Alternativ för färgformatering

Avsnittet Färger i de visuella formateringsalternativen anpassas baserat på din datakonfiguration:

• Endast plats: Ange färger med villkorsstyrd formatering eller individuellt för varje region.
• Plats och förklaring: Ange en distinkt färg för varje förklaringsvärde individuellt.
• Färgmättnad: Välj toningsfärger baserat på värdena i fältet Färgmättnad.

Du kan också anpassa tom ytfärg för regioner som inte matchar dina data och justera kantlinjefärg och tjocklek.

Exempel: Toningsfärger efter region

När du bara använder fältet Plats (utan förklaring eller färgmättnad) kan du använda villkorsstyrd formatering med ett DAX-mått för att skapa en toningseffekt inom varje region. Följande mått beräknar en hexfärg baserat på Total försäljning, där varje region använder sin egen färgpalett. Tillstånd med högre försäljning verkar mer mättade, medan tillstånd med lägre försäljning verkar lättare.

Region Gradient Color = 
VAR ScaleWithinRegion = TRUE
VAR CurrentSales = [Total Sales]

VAR ScopeMin =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MINX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR ScopeMax =
    IF (
        ScaleWithinRegion,
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALLEXCEPT ( StateRegion, StateRegion[Region] )
        ),
        CALCULATE (
            MAXX ( VALUES ( StateRegion[StateName] ), [Total Sales] ),
            ALL ( StateRegion )
        )
    )

VAR Ratio =
    DIVIDE ( CurrentSales - ScopeMin, ScopeMax - ScopeMin )

VAR Region = SELECTEDVALUE ( StateRegion[Region] )

VAR EndR = SWITCH ( Region,
    "Northwest", 17,  "Northeast", 216, "Southeast", 116,
    "Southwest", 224, "Alaska", 17,     "Hawaii", 17,    128 )
VAR EndG = SWITCH ( Region,
    "Northwest", 141, "Northeast", 106, "Southeast", 78,
    "Southwest", 68,  "Alaska", 141,    "Hawaii", 141,   128 )
VAR EndB = SWITCH ( Region,
    "Northwest", 255, "Northeast", 44,  "Southeast", 194,
    "Southwest", 68,  "Alaska", 255,    "Hawaii", 255,   128 )

VAR TintStrength = 0.15
VAR StartR = 255 - ( 255 - EndR ) * TintStrength
VAR StartG = 255 - ( 255 - EndG ) * TintStrength
VAR StartB = 255 - ( 255 - EndB ) * TintStrength

VAR R01 = MIN ( 1, MAX ( 0, Ratio ) )

VAR R = INT ( StartR + ( EndR - StartR ) * R01 )
VAR G = INT ( StartG + ( EndG - StartG ) * R01 )
VAR B = INT ( StartB + ( EndB - StartB ) * R01 )

VAR HexChars = "0123456789ABCDEF"
VAR Hex =
    "#" &
    MID ( HexChars, QUOTIENT ( R, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( R, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( G, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( G, 16 ) + 1, 1 ) &
    MID ( HexChars, QUOTIENT ( B, 16 ) + 1, 1 ) & MID ( HexChars, MOD ( B, 16 ) + 1, 1 )

RETURN
    IF ( ISBLANK ( CurrentSales ), "#FFFFFF", Hex )

Så här använder du det här måttet:

1. Lägg till måttet i din semantiska modell.
2. Lägg till platsfältet i området Plats i det visuella objektet Formkarta.
3. I fönstret Format expanderar du Färger>Plats.
4. Välj knappen Fx bredvid Standard.
5. Ange Formatformat till Fältvärde och välj måttet Region Gradient Color .

Varje tillstånd visar en färgintensitet baserat på dess försäljning i förhållande till andra tillstånd i samma region.

Hämta kartdata

Om du snabbt vill hämta data till en modell för att testa formkartan kopierar du en av tabellerna i slutet av den här artikeln och väljer sedan Ange data i menyfliksområdet Start .

Den översta raden identifieras automatiskt som en rubrik. Ange en ny kolumn genom att skriva ett nytt kolumnnamn i den tomma kolumnen till höger. Lägg till värden i varje cell precis som du kan göra i Excel. När du är klar väljer du Läs in. Tabellen läggs till i datamodellen.

Överväganden och begränsningar

Tänk på följande när du använder formkartan:

• Färgmättnad-bucketen måste ställas in för att teckenförklaring-klassificeringen ska fungera korrekt.
• Det visuella objektet Formkarta ritar upp till högst 1 500 datapunkter.

Regionnycklar

Använd följande regionnycklar för att testa formkartan.

Australien: Delstater

Österrike: Stater

Brasilien: Delstater

Kanada: Provinser

Frankrike: Regioner

Tyskland: Stater

Irland: Län

Italien: Regioner

Mexiko: Delstater

Nederländerna: Provinser

Storbritannien: Länder/regioner

USA: Delstater

Relaterat innehåll

• Mappa visualiseringar i Power BI
• Ifyllda kartor (koropletkartor) i Power BI
• Tips för kartvisualiseringar
• Villkorsstyrd formatering i Power BI
• Visualiseringstyper i Power BI