List.Distinct

Syntax

List.Distinct(list as list, optional equationCriteria as any) as list

Om

Returnerar en ny lista som innehåller alla värden i den ursprungliga listan, men med dubbletter borttagna. Om den ursprungliga listan är tom blir resultatet en tom lista.

• list: Den ursprungliga listan som de distinkta värdena extraheras från.
• equationCriteria: (Valfritt) Anger hur likhet bestäms när värden jämförs. Den här parametern kan vara en nyckelväljare, en jämförelsefunktion eller en lista som innehåller både en nyckelväljare och en jämförelse.

Exempel 1

Ta bort dubbletter från listan {1, 1, 2, 3, 3, 3}.

Användning

List.Distinct({1, 1, 2, 3, 3, 3})

Output

{1, 2, 3}

Exempel 2

Från och med slutet av listan väljer du de frukter som har en unik textlängd.

Användning

let
    Source = {"Apple", "Banana", "Cherry", "Date", "Fig"},
    Result = List.Distinct(List.Reverse(Source), each Text.Length(_))
in
    Result

Output

{"Fig", "Date", "Cherry", "Apple"}

Exempel 3

Från och med början av listan väljer du de unika frukterna samtidigt som skiftläge ignoreras.

Användning

let
    Source = {"apple", "Pear", "aPPle", "banana", "ORANGE", "pear", "Banana", "Cherry"},
    Result = List.Distinct(Source, Comparer.OrdinalIgnoreCase)
in
    Result

Output

{"apple", "Pear", "banana", "ORANGE", "Cherry"}

Exempel 4

Extrahera från en lista med listor över de första listorna med unika landsnamn samtidigt som skiftläge ignoreras. Placera de extraherade listorna i raderna i en ny tabell.

Användning

let
    Source = {
        {"USA", #date(2023, 8, 1), 567},
        {"canada", #date(2023, 8, 1), 254},
        {"Usa", #date(2023, 7, 1), 450},
        {"CANADA", #date(2023, 6, 1), 357},
        {"Panama", #date(2023, 6, 2), 20},
        {"panama", #date(2023, 7, 1), 40}
    },
    DistinctByCountry = List.Distinct(
        Source,
        {each _{0}, Comparer.OrdinalIgnoreCase}
    ),
    ToTable = Table.FromRows(DistinctByCountry, {"Country", "Date", "Value"}),
    ChangeTypes = Table.TransformColumnTypes(
        ToTable, {{"Country", type text}, {"Date", type date}, {"Value", Int64.Type}}
    )
in
    ChangeTypes

Output

#table(type table[Country = text, Date = date, Value = Int64.Type],
{
    {"USA", #date(2023, 8, 1), 567},
    {"canada", #date(2023, 8, 1), 254},
    {"Panama", #date(2023, 6, 2), 20}
})

Relaterat innehåll

Ekvationsvillkor