在 QDK 的擴充功能中為 Visual Studio Code 執行量子模擬

適用於Visual Studio Code(VS Code)的MicrosoftQDK(Quantum Development Kit)擴充功能會自動在其本地稀疏模擬器上執行Q#和OpenQASM程式。

本文說明如何在本地模擬器上執行程式,以及如何在 Q# 模擬中加入 Pauli 雜訊。 要使用來自 Python 的其他 QDK 模擬器,請參考 用 QDKPython 套件執行量子模擬。

本地模擬器的運作方式

稀疏模擬器僅儲存量子態的非零振幅。 當大多數計算基底振幅為零時,這種表示方式使用較少記憶體,且能模擬比儲存所有振幅的全狀態模擬器量子位元數更多的某些程式。

效能提升取決於量子態在計算基底中是否保持稀疏。 更多資訊請參見Jaques與Häner(arXiv:2105.01533)。

在 VS Code 中執行一個量子程式

  1. 為 VS Code 安裝 QDK 擴充功能。
  2. 打開一個 Q# (.qs) 或 OpenQASM (.qasm) 檔案。
  3. 從檔案開頭或 Q#Main 作業上方的程式碼鏡頭選取 Run。

模擬輸出會出現在 VS Code 終端機中。 對於 Q# 程式,選擇 除錯 以檢查程式執行中的量子狀態。

將Pauli雜訊加入Q#模擬

稀疏模擬器支援 Q# 擴充套件中 QDK 程式的 Pauli 噪音。 用 ConfigurePauliNoise 來設定程式中 Pauli $X$、$Y$和$Z$錯誤的機率。 QDK擴充設定也支援全域Pauli雜訊模型。

Note

你無法在 OpenQASM 擴充套件中為 QDK 模擬新增噪音模型。 若要為 Q# 或 OpenQASM 程式建立特定操作的雜訊模型,請使用套件QDKPython與 NoiseConfig API。

在Pauli設定中加入VS Code噪音

  • 在 VS Code中,於 Pauli 擴充功能的 Q#使用者設定中,為 > 程式設定全域 Q# 雜訊。

QDK中Pauli擴充功能VS Code全域Q#雜訊設定的截圖。

噪聲設定適用於所有程式Q#中VS Code所有閘、測量及量子位元的直方圖結果。

若無雜訊,該 GHZ 範例程式的直方圖顯示約一半測量值為$\ket{00000}$,另一半為$\ket{11111}$。

import Std.Diagnostics.*;
import Std.Measurement.*;

operation Main() : Result[] {
    let num = 5;
    return GHZSample(num);
}

operation GHZSample(n: Int) : Result[] {
    use qs = Qubit[n];
    H(qs[0]);
    ApplyCNOTChain(qs);
    let results = MeasureEachZ(qs);
    ResetAll(qs);
    return results;
}

一張沒有雜訊且所有量子位元為零或所有量子位元為一的峰值直方圖截圖。

在 1% 的位元翻轉雜訊率下,結果開始分散。 在 25%時,直方圖與純噪聲無異。

某程式的直方圖截圖 Q#,其位元翻轉雜訊率為 1% 和 25%。

為個別Pauli 程式加入Q# 雜訊

使用 ConfigurePauliNoise 來設定或更改 Q# 程式的噪音模型,並控制噪音何時及何地發生。

Note

VS Code 設定會對所有 Q# 程式套用雜訊,但 ConfigurePauliNoise 會為呼叫它的程式覆寫這些設定。

在前一個程式中,量子位元分配後立即加入雜訊:

operation GHZSample(n: Int) : Result[] {
    use qs = Qubit[n];

    // 5% bit-flip noise applies to all subsequent operations.
    ConfigurePauliNoise(0.05, 0.0, 0.0);

    H(qs[0]);
    ApplyCNOTChain(qs);
    let results = MeasureEachZ(qs);
    ResetAll(qs);
    return results;
}

當 5% 位元翻轉雜訊在量子位元分配後開始出現時的直方圖結果截圖。

若要僅對測量操作施加雜訊,請在測量前立即設定雜訊模型,測量後再清除:

operation GHZSample(n: Int) : Result[] {
    use qs = Qubit[n];
    H(qs[0]);
    ApplyCNOTChain(qs);

    // Noise applies only to the measurement operation.
    ConfigurePauliNoise(0.05, 0.0, 0.0);

    let results = MeasureEachZ(qs);
    ResetAll(qs);
    return results;
}

當 5% 位元翻轉雜訊在測量前立即開始時,直方圖的截圖結果。

要在程式不同階段更改或清除雜訊配置,請多次呼叫 ConfigurePauliNoise 。 例如,對 Hadamard 閘施加 5% 位元翻轉雜訊,然後清除程式其餘部分的雜訊設定。

operation GHZSample(n: Int) : Result[] {
    use qs = Qubit[n];

    // Noise applies to the H operation.
    ConfigurePauliNoise(0.05, 0.0, 0.0);
    
    H(qs[0]);

    // Clear the noise settings.
    ConfigurePauliNoise(0.0, 0.0, 0.0);
    
    ApplyCNOTChain(qs);
    let results = MeasureEachZ(qs);
    ResetAll(qs);
    return results;
}

其他 Q# 噪聲函數

ConfigurePauliNoise 支援任何 Pauli 噪音模型。 利用命名空間中的 Std.Diagnostics 這些函式與操作來配置或套用雜訊:

函數 Description Example
ConfigurePauliNoise 設定 Pauli 模擬的噪音。 傳遞 Pauli $X$、$Y$ 和 $Z$ 錯誤的機率,或是 Pauli 噪音模型。 此配置適用於 Q# 程式中所有後續閘、測量及量子位元,並覆寫 VS Code 擴充功能噪聲設定。 後續呼叫會覆蓋先前的設定。 ConfigurePauliNoise(0.1, 0.0, 0.5)
或
ConfigurePauliNoise(BitFlipNoise(0.1))
BitFlipNoise 回傳一個在指定機率下僅包含 Pauli $X$ 誤差的雜訊模型。 10% 位元翻轉雜訊:
ConfigurePauliNoise(BitFlipNoise(0.1)) $\等價$ ConfigurePauliNoise(0.1, 0.0, 0.0)
PhaseFlipNoise 回傳一個在指定機率下僅 Pauli 有$Z$誤差的雜訊模型。 10% 相位翻轉雜訊:
ConfigurePauliNoise(PhaseFlipNoise(0.1)) $\等價$ ConfigurePauliNoise(0.0, 0.0, 0.1)
DepolarizingNoise 回傳一個噪音模型,錯誤機率相等,分別為 Pauli $X$、$Y$ 和 $Z$ 錯誤。 6% 去極化雜訊:
ConfigurePauliNoise(DepolarizingNoise(0.06)) $\等價$ ConfigurePauliNoise(0.02, 0.02, 0.02)
NoNoise 回傳一個錯誤機率為零的模型。 把它傳給 ConfigurePauliNoise 以清除目前的噪音配置。 ConfigurePauliNoise(NoNoise()) $\等價$ ConfigurePauliNoise(0.0, 0.0, 0.0)
ApplyIdleNoise 在模擬期間將設定的雜訊套用至單一量子位元。 ...
use q = Qubit[2];
ConfigurePauliNoise(0.1, 0.0, 0.0);
ApplyIdleNoise(q[0]);
...