Azure 虛擬桌面 中 session host 更新的診斷查詢範例

會話主機更新使用 Azure Monitor 中的日誌分析來儲存更新資訊。 這篇文章有一些範例 Kusto 查詢,你可以用 Log Analytics 來查看有關會話主機更新的資訊。

必要條件

在使用這些查詢之前,你需要:

  • 一個現有的主機池,並設定為會話主機。

  • 在你使用的每個主機池上設定 診斷設定 ,並透過會話主機更新將日誌和指標傳送到日誌分析工作區。 至少必須啟用檢查 點、 錯誤及 會話主機管理活動日誌 這些類別。

  • 預先 排程並執行會話主機更新 ,針對主機池中的會話主機。

診斷資料位置

一旦你在主機池上設定診斷設定,會話主機更新的診斷資料會儲存在你的 Log Analytics 工作區的表格 WVDSessionHostManagement 和 WVDCheckpoints 資料夾中。 日誌條目使用現有的管理活動類型,該類型來自Azure Resource Manager (ARM) 提供者。

該表格 WVDSessionHostManagement 專門針對會話主機更新,並在你使用與會話主機更新並執行時,啟用了診斷設定中的 「會話主機管理活動日誌 」類別,並執行會話主機更新後建立。 如果你之前已設定過主機池的診斷設定,你需要啟用 「會話主機管理活動日誌」類別。 欲了解更多資訊,請配置診斷設定以擷取 Azure 虛擬桌面的平台日誌與指標。

本文其餘部分有一些你可以執行的範例查詢。 你可以用它們作為基礎,自行創建查詢。 你需要在 Log Analytics 中執行這些查詢。 欲了解更多如何執行查詢的資訊,請參閱 「開始日誌分析」。

已成功完成的會話主機更新

此查詢會將表格WVDSessionHostManagementWVDCheckpoints相關,並提供完成更新所需的時間,以及過去 30 天內更新單一會話主機的中位時間(分鐘):

let timeRange                               = ago(30d);
let succeededStatus                         = "Succeeded";
let hostPoolUpdateCompletedCheckpoint       = "HostPoolUpdateCompleted";
let sessionHostUpdateCompletedCheckpoint    = "SessionHostUpdateCompleted";
let provisioningTypeUpdate                  = "Update";
WVDSessionHostManagement
| where ProvisioningStatus == succeededStatus and TimeGenerated >= timeRange and ProvisioningType == provisioningTypeUpdate
| join kind = inner (
      // Get number of session hosts updated
    WVDCheckpoints
    | where Name == hostPoolUpdateCompletedCheckpoint
    | extend ParametersParsed = parse_json(Parameters)
    | extend SessionHostUpdateCount = ParametersParsed["SessionHostsUpdateCompleted"], UpdateCompletionTime = todatetime(ParametersParsed["TimeCompleted"]), UpdateStartTime = todatetime(ParametersParsed["TimeStarted"])
    | project CorrelationId, SessionHostUpdateCount, UpdateStartTime, UpdateCompletionTime
) on CorrelationId
| join kind = inner
(
      // Get time to update individual session hosts
    WVDCheckpoints
    | where Name == sessionHostUpdateCompletedCheckpoint
    | extend ParametersParsed = parse_json(Parameters)
    | extend SessionHostUpdateTime = todecimal(ParametersParsed["TimeTakenToUpdateSessionHostInSeconds"])
    // Calculate median time to update session host
    | summarize SessionHostMedianUpdateTime = percentile(SessionHostUpdateTime, 50) by CorrelationId
) on CorrelationId
| project TimeGenerated, _SubscriptionId, _ResourceId, CorrelationId, UpdateStartDateTime = UpdateStartTime, UpdateEndDateTime = UpdateCompletionTime, ['UpdateDuration [InMinutes]'] = datetime_diff('minute', UpdateCompletionTime, UpdateStartTime), SessionHostUpdateCount, ['MedianSessionHostUpdateTime [InMinutes]'] = toint(SessionHostMedianUpdateTime/(60 * 1.0)), UpdateBatchSize = UpdateMaxVmsRemoved, FromSessionHostConfigVer, ToSessionHostConfigVer, UpdateDeleteOriginalVm

回傳的資料集如下:

欄 定義
時間生成 系統產生的事件時間戳記
_SubscriptionId 主機池的訂閱 ID
_ResourceId 主機池的資源識別碼
相關性 為主機池上每次影像更新所分配的唯一識別碼
更新開始日期時間 會話主機更新 UTC 開始時間戳
更新結束日期時間 會議主機更新完成時間戳記(UTC)
更新時長 更新主機池中所有會話主機映像所需的時間,需幾分鐘
SessionHostUpdateCount 更新的會話主機數量
MedianSessionHostUpdateTime 更新單一會話主機映像的中位數時間(幾分鐘)
更新批次大小 在映像更新時,單一批次中存在的會話主機數量
FromSessionHostConfigVer 更新映像前的會話主機設定
ToSessionHostConfigVer 影像更新後的會話主機設定
更新刪除原始VMM 原始虛擬機在映像更新完成後是否被保留

會話主機更新期間的錯誤

此查詢會將資料表 WVDSessionHostManagement 相關化,並提供 WVDErrors 你過去 30 天內在會話主機更新時排除錯誤的資訊:

let timeRange               = ago(30d);
let provisioningTypeUpdate  = "Update";
WVDSessionHostManagement
| where ProvisioningStatus  in ("Failed", "Error", "Canceled") and TimeGenerated >= timeRange and ProvisioningType == provisioningTypeUpdate
| summarize arg_max(TimeGenerated, _ResourceId, _SubscriptionId, FromSessionHostConfigVer, ToSessionHostConfigVer) by CorrelationId
| join kind = inner 
(
      // Get image update errors
    WVDErrors
    | where TimeGenerated >= timeRange
    | extend IsSessionHostResourceIdAvailable = iif(Message startswith "SessionHostResourceId", 1, 0)
    | extend startIndex = iif(IsSessionHostResourceIdAvailable == 1, indexof(Message, ":") + 1, 0)
    | extend length = iif(IsSessionHostResourceIdAvailable == 1, indexof(Message, ";") - startIndex, 0)
    // Get Session host ResourceId when available
    | extend SessionHostResourceId = iif(IsSessionHostResourceIdAvailable == 1, substring(Message, startIndex, length), "")
    | project TimeGenerated, CorrelationId, SessionHostResourceId, CodeSymbolic, Message
) on CorrelationId
| project TimeGenerated, _SubscriptionId, _ResourceId, CorrelationId, CodeSymbolic, SessionHostResourceId, Message, FromSessionHostConfigVer, ToSessionHostConfigVer

回傳的資料集如下:

欄 定義
時間生成 系統產生的事件時間戳記
_SubscriptionId 主機池的訂閱 ID
_ResourceId 主機池的資源識別碼
相關性 為主機池上每次影像更新所分配的唯一識別碼
CodeSymbolic 錯誤碼
SessionHostResourceId 若適用,請提供會話主機的資源 ID
郵件 錯誤資訊
FromSessionHostConfigVer 會話主機設定版本,更新映像前
ToSessionHostConfigVer 會話主機設定版本,更新過程中會話主機更新,導致更新失敗

管理員在預定時間前取消會話主機更新

此查詢將資料表 WVDSessionHostManagement 及 WVDCheckpoints 會話主機更新相關聯,這些更新已排程,但管理員在啟動前取消,且發生於 30 天內:

let timeRange                           = ago(30d);
let canceledStatus                      = "Canceled";
let scheduledStatus                     = "Scheduled";
let hostPoolUpdateCanceledCheckpoint    = "HostPoolUpdateCanceled";
let provisioningTypeUpdate              = "Update";
WVDSessionHostManagement
| where ProvisioningStatus == canceledStatus and TimeGenerated >= timeRange and ProvisioningType == provisioningTypeUpdate
| join kind = inner
(
    WVDCheckpoints
    | where Name == "HostPoolUpdateCanceled"
    | project TimeGenerated, CorrelationId, Name, Parameters
    | extend ParametersParsed = parse_json(Parameters)
    | extend StateFrom = tostring(ParametersParsed["StateFrom"]), StateTo = tostring(ParametersParsed["StateTo"]), CanceledTime = todatetime(ParametersParsed["TimeCanceled"])
    | where StateFrom == scheduledStatus and StateTo == canceledStatus
) on CorrelationId
| project TimeGenerated, _SubscriptionId, _ResourceId, CorrelationId, ScheduledDateTime = todatetime(ScheduledDateTime), CanceledDateTime = CanceledTime, UpdateBatchSize = UpdateMaxVmsRemoved

回傳的資料集如下:

欄 定義
時間生成 系統產生的事件時間戳記
_SubscriptionId 主機池的訂閱 ID
_ResourceId 主機池的資源識別碼
相關性 每次主機池映像更新時,唯一識別碼
預定日期時間 會議主持人更新 排程時間(UTC)
取消日期時間 UTC 時間,管理員取消了圖片更新
更新批次大小 在映像更新時,單一批次中存在的會話主機數量

正在進行或失敗,後來被管理員取消的會話主機更新

此查詢會關聯這些資料表 WVDSessionHostManagement ,並提供 WVDCheckpoints 正在進行中或失敗後,管理員在過去 30 天內取消的會話主機更新:

let timeRange                           = ago(30d);
let canceledStatus                      = "Canceled";
let scheduledStatus                     = "Scheduled";
let hostPoolUpdateCanceledCheckpoint    = "HostPoolUpdateCanceled";
let provisioningTypeUpdate              = "Update";
WVDSessionHostManagement
| where ProvisioningStatus == canceledStatus and TimeGenerated >= timeRange and ProvisioningType == provisioningTypeUpdate
| join kind = inner
(
    WVDCheckpoints
    | where Name == hostPoolUpdateCanceledCheckpoint
    | project TimeGenerated, CorrelationId, Name, Parameters
    | extend ParametersParsed = parse_json(Parameters)
    | extend StateFrom = tostring(ParametersParsed["StateFrom"]), StateTo = tostring(ParametersParsed["StateTo"]), CanceledTime = todatetime(ParametersParsed["TimeCanceled"]), TotalSessionHostsInHostPool = toint(ParametersParsed["TotalSessionHostsInHostPool"]), SessionHostUpdateCount = ParametersParsed["SessionHostsUpdateCompleted"]
    | where StateFrom != scheduledStatus and StateTo == canceledStatus
) on CorrelationId
| project TimeGenerated, _SubscriptionId, _ResourceId, CorrelationId, ScheduledDateTime = todatetime(ScheduledDateTime), CanceledDateTime = CanceledTime, TotalSessionHostsInHostPool, SessionHostUpdateCount, UpdateBatchSize = UpdateMaxVmsRemoved

回傳的資料集如下:

欄 定義
時間生成 系統產生的事件時間戳記
_SubscriptionId 主機池的訂閱 ID
_ResourceId 主機池的資源識別碼
相關性 為主機池中會話主機的每次更新所指派的唯一識別碼
預定日期時間 會議主持人更新 排程時間(UTC)
取消日期時間 UTC 時間,管理員取消了會話主機的更新
TotalSessionHostsInHostPool 主機池中會話主機總數
SessionHostUpdateCount 在取消會話主機更新前,已更新的會話主機數量
更新批次大小 更新會話主機時,單批次中會話主機數量

每次會話主機更新的狀態

此查詢會將表格WVDSessionHostManagementWVDCheckpoints相關,並提供過去 30 天內每個會話主機更新的最新狀態:

let timeRange                               = ago(30d);
let sessionHostUpdateCompletedCheckpoint    = "SessionHostUpdateCompleted";
let provisioningTypeUpdate                  = "Update";
WVDSessionHostManagement
| where TimeGenerated >= timeRange and ProvisioningType == provisioningTypeUpdate
| join kind = leftouter (
      // Get number of session hosts updated if available
    WVDCheckpoints
    | where Name == sessionHostUpdateCompletedCheckpoint
    | summarize SessionHostUpdateCount = count() by CorrelationId
) on CorrelationId
| summarize arg_max(TimeGenerated, _SubscriptionId, _ResourceId, ScheduledDateTime, UpdateMaxVmsRemoved, SessionHostUpdateCount, ProvisioningStatus) by CorrelationId
| project TimeGenerated, _SubscriptionId, _ResourceId, CorrelationId, ProvisioningStatus, ScheduledDateTime = todatetime(ScheduledDateTime), UpdateBatchSize = UpdateMaxVmsRemoved, SessionHostUpdateCount = iif(isempty(SessionHostUpdateCount), 0, SessionHostUpdateCount)

回傳的資料集如下:

欄 定義
時間生成 系統產生的事件時間戳記
_SubscriptionId 主機池的訂閱 ID
_ResourceId 主機池的資源識別碼
相關性 每次主機池映像更新時,唯一識別碼
配置狀態 主機池映像更新的當前狀態
預定日期時間 會議主持人更新 排程時間(UTC)
更新批次大小 在影像更新時,單批次中會話主機的數量
SessionHostUpdateCount 更新的會話主機數量

後續步驟

有關會話主機更新的故障排除指引,請參見 「故障排除會話主機更新」。