Access) (Report.Circle 方法

Circle 方法會在 Print 事件發生時，在報表物件上繪製圓形、橢圓或弧線。

語法

運算式。圓形 (步驟 (x、y) 、 半徑、 色彩、 開始、 結束、 外觀)

運算式 代表 Report 物件的變數。

參數

名稱 資料類型 描述
步驟 關鍵字 表示圓、橢圓或圓弧的中心是相對於 Object 引數之 CurrentX 和 CurrentY 屬性的目前設定所提供的目前座標。
(x、y) Single 表示圓、橢圓或圓弧的中心點座標。Object 引數所指定 Report 物件的 Scale 屬性 (ScaleMode、ScaleLeft、ScaleTop、ScaleHeight 和 ScaleWidth 屬性) 決定使用的度量單位。
Radius Single 表示圓、橢圓或圓弧的半徑。Object 引數所指定 Report 物件的 Scale 屬性 (ScaleMode、ScaleLeft、ScaleTop、ScaleHeight 和 ScaleWidth) 決定使用的度量單位。 根據預設，距離是以 twips 為單位進行測量。
Color Long 表示圓形外框的 RGB (紅-綠-藍) 色彩。 如果省略此引數，則會使用 ForeColor 屬性的值。 您也可以使用 RGB 函數或 QBColor 函數來指定色彩。
Start Single 繪製部分圓或橢圓時， Start 引數會以弧度) 弧的起始位置指定 (。 Start 引數的預設值為 0 弧度。 範圍是 -2 pi 弧度到 2 pi 弧度。
End Single 繪製部分圓或橢圓時， End 引數會以弧度) 弧的結束位置指定 (。 End 引數的預設值為 2 pi 弧度。 範圍是 -2 pi 弧度到 2 pi 弧度。
外觀 Single 表示圓的外觀比例。 預設值為 1.0，會在任何畫面上產生完美的 (非橢圓) 圓形。

註解

此方法僅在由報表區段的事件屬性或報表的 OnPage 事件屬性所指定的事件程序或巨集中使用。

繪製部分圓形或橢圓時，如果 Start 引數為負數， Circle 方法會將半徑繪製到 Start 引數所指定的位置，並將該角度視為正數。 如果 End 引數為負數， Circle 方法會在 End 引數所指定的位置繪製半徑，並再次將該角度視為正數。 Circle 方法會固定以逆時針 (正) 方向繪製。

若要填滿圓形，請設定報表的 FillColor 和 FillStyle 屬性。 只有封閉圖形可以填滿。 封閉圖形包括圓形、橢圓形及圓形切片，其為在兩端繪製半徑線條的弧形。

繪製圓形圖切片時，如果您需要繪製角度為 0 的半徑以向右形成水平線段，請為 Start 引數指定一個非常小的負值，而不是 0。 例如，您可以為 Start 引數指定 -.00000001。

您可以省略語法中間的引數，但是必須在下一個引數之前加入引數的逗號。 如果您省略結尾引數，請勿在您指定的最後一個引數後面使用任何逗號。

用來繪製圓、橢圓或圓弧的線條寬度取決於 DrawWidth 屬性設定。 在背景上繪製圓圈的方式取決於 DrawMode 和 DrawStyle 屬性的設定。

當您套用 Circle 方法時，CurrentX 及 CurrentY 屬性會設定為x 及 y 引數所指定的中心點。

範例

以下範例使用 Circle 方法繪製圓形，然後在圓形內建立圓形切片，並以紅色著色。

若要在 Microsoft Access 中嘗試此範例，請建立一個新報表。 將詳細資料區段的 OnPrint 屬性設定為 [事件程序]。 在報表的模組中輸入下列程式碼，然後切換到 [預覽列印]。

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    Const conPI = 3.14159265359 
    Dim sngHCtr As Single, sngVCtr As Single 
    Dim sngRadius As Single 
    Dim sngStart As Single, sngEnd As Single 
 
    sngHCtr = Me.ScaleWidth / 2     ' Horizontal center. 
    sngVCtr = Me.ScaleHeight / 2     ' Vertical center. 
    sngRadius = Me.ScaleHeight / 3     ' Circle radius. 
    ' Draw circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius 
    sngStart = -0.00000001             ' Start of pie slice. 
    sngEnd = -2 * conPI / 3             ' End of pie slice. 
    Me.FillColor = RGB(255,0,0)     ' Color pie slice red. 
    Me.FillStyle = 0                     ' Fill pie slice. 
    ' Draw pie slice within circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius, , sngStart, sngEnd 
End Sub

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。

  • Last updated on