代表已安裝或未安裝的單一增益集。
註解
AddIn 物件是 AddIns 集合的成員。 增 益集 集合包含 Microsoft Excel 可用的所有增益集清單，無論它們是否已安裝。 這個清單就是顯示在 [增益集] 對話方塊中的增益集清單。
範例
使用 AddIns (索引) ， 其中 index 是增益集標題或索引號碼，以傳回單一 AddIn 物件。 下列範例會安裝「分析工具箱」增益集。
AddIns("analysis toolpak").Installed = True
請勿混淆 [ 增益集 ] 對話方塊中顯示的增益集標題與增益集名稱，也就是增益集的檔案名稱。 增益集標題的拼字必須完全符合 [增益集] 對話方塊中的拼字，但大小寫不一定要相符。
增益集的索引編號代表增益集在 [增益集] 對話方塊內 [現有的增益集] 方塊中的位置。 下列範例會建立一份清單，其中包含現有增益集的指定屬性。
With Worksheets("sheet1")
.Rows(1).Font.Bold = True
.Range("a1:d1").Value = _
Array("Name", "Full Name", "Title", "Installed")
For i = 1 To AddIns.Count
.Cells(i + 1, 1) = AddIns(i).Name
.Cells(i + 1, 2) = AddIns(i).FullName
.Cells(i + 1, 3) = AddIns(i).Title
.Cells(i + 1, 4) = AddIns(i).Installed
Next
.Range("a1").CurrentRegion.Columns.AutoFit
End With
Add 方法會將增益集新增至可用增益集清單，但不會安裝增益集。 若要安裝增益集，請將增益集的 Installed 屬性設定為 True。
若要安裝未出現在可用增益集清單中的增益集，您必須先使用 Add 方法，然後設定 Installed 屬性。 這個程序可用一個步驟完成，如下列範例所示 (請注意，Add 方法使用的是增益集名稱，而非增益集標題)。
AddIns.Add("generic.xll").Installed = True
使用 Workbooks (索引) ，其中 index 是增益集檔案名稱， (不是標題) ，以傳回對應已載入增益集的活頁簿參照。 您必須使用檔案名稱，因為載入的增益集通常不會出現在 [活頁簿 ] 集合中。 這個範例會將變數 wb 設定為 Myaddin.xla 所在的活頁簿。
Set wb = Workbooks("myaddin.xla")
下列範例會將變數 wb 設定為 [分析工具箱] 增益集所在的活頁簿。
Set wb = Workbooks(AddIns("analysis toolpak").Name)
如果 Installed 屬性傳回 True，但對增益集內函數的呼叫仍然失敗，則實際上可能不會載入增益集。 這是因為 Addin 物件代表增益集的存在與安裝狀態，並不代表增益集活頁簿的實際內容。若要確保已載入已安裝的增益集，您應該開啟增益集活頁簿。
如果 [活頁簿 ] 集合中沒有名為「我的增益集」的增益集，下列範例會開啟該增益集的活頁簿。
On Error Resume Next ' turn off error checking
Set wbMyAddin = Workbooks(AddIns("My Addin").Name)
lastError = Err
On Error Goto 0 ' restore error checking
If lastError <> 0 Then
' the add-in workbook isn't currently open. Manually open it.
Set wbMyAddin = Workbooks.Open(AddIns("My Addin").FullName)
End If
屬性
另請參閱
支援和意見反應
有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。