Excel) (CalculatedMembers.Add 方法

會將計算欄位或計算項目新增到樞紐分析表中。 傳回 CalculatedMember 物件。

語法

運算式。新增 (Name、 Formula、 SolveOrder、 Type、 Dynamic、 DisplayFolder、 HierarchizeDistinct)

運算式 代表 CalculatedMembers 物件的變數。

參數

名稱 必要/選用 資料類型 描述
Name 必要 字串 計算成員的名稱。
公式 必要 字串 計算成員所用的公式。
SolveOrder 選用 Variant 計算成員的求解順序。
類型 選用 Variant 計算成員的類型。
Dynamic 選用 布林值 指定是否在每次更新時重新計算計算成員。
DisplayFolder 選用 字串 計算成員的顯示資料夾名稱。
HierarchizeDistinct 選用 布林值 指定在以 OLAP Cube 為基礎的樞紐分析表中顯示計算成員階層時，是否要排序並移除重複項目。

傳回值

代表新計算欄位或新計算項目的 CalculatedMember 物件。

註解

Formula 引數必須包含有效的 MDX (多維度運算式) 語法陳述式。 線上分析處理 (OLAP) 提供者必須可以接受 Name 引數，而且必須定義 Type 引數。

如果您將這個方法的 Type 引數設為 xlCalculatedSet，您必須呼叫 CubeFields 物件的 AddSet 方法，才能讓新的欄位集顯示在樞紐分析表中。

範例

下列範例會在樞紐分析表中新增集合，並假設樞紐分析表是位於現用工作表上。

注意事項

必須連線至此 Cube 和現有的樞紐分析表，才能執行範例。

Sub UseAddSet() 
 
 Dim pvtOne As PivotTable 
 Dim strAdd As String 
 Dim strFormula As String 
 Dim cbfOne As CubeField 
 
 Set pvtOne = ActiveSheet.PivotTables(1) 
 
 strAdd = "[MySet]" 
 strFormula = "'{[Product].[All Products].[Food].children}'" 
 
 ' Establish connection with data source if necessary. 
 If Not pvtOne.PivotCache.IsConnected Then pvtOne.PivotCache.MakeConnection 
 
 ' Add a calculated member titled "[MySet]" 
 pvtOne.CalculatedMembers.Add Name:=strAdd, _ 
 Formula:=strFormula, Type:=xlCalculatedSet 
 
 ' Add a set to the CubeField object. 
 Set cbfOne = pvtOne.CubeFields.AddSet(Name:="[MySet]", _ 
 Caption:="My Set") 
 
End Sub

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。

  • 上次更新時間：