Outlook) (RecurrencePattern.DayOfWeekMask 屬性

傳回或設定 OlDaysOfWeek 常數,代表一週當中發生週期性約會或工作日期的遮罩。 讀取/寫入。

語法

expression。 DayOfWeekMask

運算式 代表 RecurrencePattern 物件的變數。

註解

DayOfWeekMask 應在設定 RecurrenceType 屬性之後,以及設定 PatternEndDate 和 PatternStartDate 屬性之前設定。

每月和每年模式只對單一的日子有效。 每週模式只有在當做 DayOfWeekMask 的 Or 時才有效。

範例

此 Visual Basic for Applications 範例使用 GetRecurrencePattern 來取得新建立之 AppointmentItem 的 RecurrencePattern 物件。 設定 RecurrenceType、 DayOfWeekMask、 PatternStartDate、 PatternEndDate、 Duration、 StartTime、 EndTime 及 Subject 屬性,並儲存約會,然後以下列模式顯示:「從 2006 年 7 月 10 日到晚上 8 月 25 日,每週一、三、五下午 2:00 至下午 3:00 發生。」

Sub RecurringAppointmentEveryMondayWednesdayFriday() 
 
 Dim oAppt As AppointmentItem 
 
 Dim oPattern As RecurrencePattern 
 
 Set oAppt = Application.CreateItem(olAppointmentItem) 
 
 Set oPattern = oAppt.GetRecurrencePattern 
 
 With oPattern 
 
 .RecurrenceType = olRecursWeekly 
 
 .DayOfWeekMask = olMonday Or olWednesday Or olFriday 
 
 .PatternStartDate = #7/10/2006# 
 
 .PatternEndDate = #8/25/2006# 
 
 .Duration = 60 
 
 .StartTime = #2:00:00 PM# 
 
 .EndTime = #3:00:00 PM# 
 
 End With 
 
 oAppt.Subject = "Recurring Appointment Monday Wednesday Friday" 
 
 oAppt.Save 
 
 oAppt.Display 
 
End Sub

與上述範例相似,這個 Visual Basic for Applications 範例也會使用 GetRecurrencePattern 來取得最近建立的 AppointmentItem 所需的 RecurrencePattern 物件。 設定 RecurrenceType、 DayOfWeekMask、 PatternStartDate、 PatternEndDate、 Duration、 StartTime、 EndTime 和 Subject 屬性,儲存約會,然後以下列模式顯示:「每週一、星期二、星期三、星期四和星期五,從 2006 年 7 月 10 日到 2006 年 8 月 4 日生效。」

Sub RecurringEventEveryWeekday() 
 
 Dim oPattern As Outlook.RecurrencePattern 
 
 Dim oAppt As Outlook.AppointmentItem 
 
 Set oAppt = Application.CreateItem(olAppointmentItem) 
 
 Set oPattern = oAppt.GetRecurrencePattern 
 
 With oPattern 
 
 .RecurrenceType = olRecursWeekly 
 
 .DayOfWeekMask = olMonday Or olTuesday Or olWednesday Or olThursday Or olFriday 
 
 .PatternStartDate = #7/10/2006# 
 
 .PatternEndDate = #8/4/2006# 
 
 .Duration = 1440 'Duration in minutes, for all day event = 24 * 60 
 
 .StartTime = #12:00:00 AM# 
 
 .EndTime = #12:00:00 AM# 
 
 End With 
 
 oAppt.Subject = "Recurring Event Every Weekday" 
 
 oAppt.Save 
 
 oAppt.Display 
 
End Sub

另請參閱

RecurrencePattern 物件

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎? 如需取得支援服務並提供意見反應的相關指導,請參閱 Office VBA 支援與意見反應。