Visio (的 Page.Drop 方法)

藉由將物件放在主圖形、繪圖頁、圖形或群組等接收物件上，建立一或多個新的 Shape 物件。

語法

運算式。卸 (ObjectToDrop、 xPos、 yPos)

表達 代表 Page 物件的變數。

參數

名稱 必要/選用 資料類型 描述
ObjectToDrop 必要 [UNKNOWN] 要卸載的物件或選取範圍。 雖然這通常是 Visio 物件，例如 Master、 Shape或 Selection 物件，但它可以是提供 IDataObject 介面的任何 OLE 物件。
xPos 必要 雙精確度 放置圖形寬度中心或 PinX 的 x 座標。
yPos 必要 雙精確度 放置圖形高度中心或 PinY 的 y 座標。

傳回值

圖形

註解

使用 Drop 方法類似以滑鼠移動圖形。 放置的物件 (ObjectToDrop) 可以是繪圖頁面上的一個主圖形或圖形。

若要將圖形加入群組或繪圖頁面上，請分別將 Drop 方法套用至 Shape 或 Page 物件。 圖形寬度高度方塊的中心位於指定的座標上，而且會傳回代表所建立之圖案的 Shape 物件。 將這個方法套用至 Shape 物件時，請確定 Shape 物件代表群組。

如果 ObjectToDrop 是一個 Master，主圖形的針會放在指定的座標上。 主圖形的針腳通常 (但不一定) 位於它的旋轉中心上。

如果您的 Visual Studio 解決方案包含 Microsoft.Office.Interop.Visio 參考，此方法會對應至下列類型：

  • Microsoft.Office.Interop.Visio.IVPage.Drop (物件、double、double)

範例

下列範例將示範如何使用 Drop 方法，將圖形放到 Page 及 Shape 物件上。

 
Public Sub Drop_Example() 
  
    Dim vsoShape1 As Visio.Shape  
    Dim vsoShape2 As Visio.Shape  
    Dim vsoShape3 As Visio.Shape  
    Dim vsoGroupShape As Visio.Shape  
    Dim vsoSubShape As Visio.Shape  
    Dim vsoSelection As Visio.Selection 
  
    Set vsoShape1 = ActivePage.DrawRectangle(1, 2, 2, 1)  
    Set vsoShape2 = ActivePage.DrawRectangle(1, 4, 2, 3)  
 
    'Drop a shape on the page.  
    Set vsoShape3 = ActivePage.Drop(vsoShape1, 3.5, 3.5)  
 
    'Make sure only one shape is selected to start.  
    Set vsoSelection = ActiveWindow.Selection 
    vsoSelection.Select vsoShape1, visDeselectAll + visSelect  
    vsoSelection.Select vsoShape2, visSelect  
 
    'Create a group shape.  
    Set vsoGroupShape = vsoSelection.Group  
 
    'Drop a shape on the group shape to create a new subshape.  
    Set vsoSubShape = vsoGroupShape.Drop(vsoShape3, 1, 2)  
 
End Sub

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。

  • 上次更新時間：