Visio) (Path.Points 方法

會傳回定義聚合線的點陣列，此聚合線近似於指定容錯程度內的 Path 或 Curve 物件。

語法

運算式。點 (容差、 xyArray () )

運算式 代表 Path 物件的變數。

參數

名稱 必要/選用 資料類型 描述
Tolerance 必要 雙精確度 指定傳回的點陣列必須近似於真正路徑的程度。
xyArray () 必要 雙精確度 輸出參數。 會傳回由 x 及 y 值交互組成的陣列，這些值會指定沿著路徑或曲線筆劃的點。

傳回值

無

註解

使用 Path 或 Curve 物件的 Points 方法來取得 x，y 座標陣列，指定指定指定容差內路徑或曲線上的點。 公差和傳回的 x，y 值以內部圖面單位表示 (英吋) 。

如果您使用 Shapes 物件的 Paths 屬性來取得所查詢的 Path 或 Curve 物件，則會在父系的座標系統中表示這些座標。 如果您使用 Shape 物件的 PathsLocal 屬性來取得 Path 或 Curve 物件，則會在本機座標系統中表示這些座標。

如果 Microsoft Visio 無法達到要求的容差，Visio 會盡可能近似接近要求的容差的點。 一般而言，容差越低，Visio 傳回的分數就越多。 Visio 不接受零 (0) 的容差。

傳回的陣列會包含路徑或曲線的開始及結束點 (即使路徑或曲線為封閉形式時亦然)。

範例

這個 Microsoft Visual Basic for Applications (VBA) 巨集會將圖形放在頁面上，並擷取它的 Paths 集合，然後使用 Path 物件的 Points 方法來傳回點的陣列，此陣列會定義近似於 Path 物件的聚合線。

 
Public Sub Points_Example() 
 
 Dim vsoShape As Visio.Shape 
 Dim adblXYPoints() As Double 
 Dim strPointsList As String 
 Dim intOuterLoopCounter As Integer 
 Dim intInnerLoopCounter As Integer 
 
 Set vsoShape = ActivePage.DrawOval(1, 1, 4, 4) 
 
 For intOuterLoopCounter = 1 To vsoShape.Paths.Count 
 
 vsoShape.Paths(intOuterLoopCounter).Points 0.1, adblXYPoints 
 For intInnerLoopCounter = LBound(adblXYPoints) To UBound(adblXYPoints) 
 strPointsList = strPointsList & adblXYPoints(intInnerLoopCounter) & Chr(10) 
 Next intInnerLoopCounter 
 
 Next intOuterLoopCounter 
 
 Debug.Print strPointsList 
 
End Sub

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。

  • 上次更新時間：