Visio) (Shape.Drop 方法

將物件拖放到接收物件上，例如主版、繪圖頁面、圖形或群組，以建立一或多個新的 Shape 物件。

語法

運算式。Drop (ObjectToDrop、 xPos、 yPos)

expression 一個用於表示 Shape 物件的變數。

參數

名稱 必要/選用 資料類型 描述
ObjectToDrop 必要 [未知] 要放置的物件或選取範圍。 雖然這通常是 Visio 物件，例如 Master、 Shape 或 Selection 物件，但也可以是任何提供 IDataObject 介面的 OLE 物件。
xPos 必要 雙精確度 放置圖形寬度中心或 PinX 的 x 座標。
yPos 必要 雙精確度 放置圖形高度中心或 PinY 的 y 座標。

傳回值

圖形

註解

使用 Drop 方法類似以滑鼠移動圖形。 放在 ObjectToDrop) ( 物件可以是繪圖頁面上的主圖形或圖形。

若要將圖形新增至群組或繪圖頁面上，請將 Drop 方法套用至 Shape 物件。 圖形的寬高方塊中心會位於指定的座標，並傳回代表所建立圖形的 Shape 物件。 將此方法套用至 Shape 物件時，請確定 Shape 物件代表群組。

如果 ObjectToDrop 是一個 Master，主圖形的針會放在指定的座標上。 主圖形的針通常 (但不一定) 位於它的旋轉中心上。

範例

下列範例將示範如何使用 Drop 方法，將圖形放到 Page 及 Shape 物件上。

 
Public Sub Drop_Example() 
 
 Dim vsoShape1 As Visio.Shape 
 Dim vsoShape2 As Visio.Shape 
 Dim vsoShape3 As Visio.Shape 
 Dim vsoGroupShape As Visio.Shape 
 Dim vsoSubShape As Visio.Shape 
 Dim vsoSelection As Visio.Selection 
 
 Set vsoShape1 = ActivePage.DrawRectangle(1, 2, 2, 1) 
 Set vsoShape2 = ActivePage.DrawRectangle(1, 4, 2, 3) 
 
 'Drop a shape on the page. 
 Set vsoShape3 = ActivePage.Drop(vsoShape1, 3.5, 3.5) 
 
 'Make sure only one shape is selected to start. 
 Set vsoSelection = ActiveWindow.Selection 
 vsoSelection.Select vsoShape1, visDeselectAll + visSelect 
 vsoSelection.Select vsoShape2, visSelect 
 
 'Create a group shape. 
 Set vsoGroupShape = vsoSelection.Group 
 
 'Drop a shape on the group shape to create a new subshape. 
 Set vsoSubShape = vsoGroupShape.Drop(vsoShape3, 1, 2) 
 
End Sub

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎？ 如需取得支援服務並提供意見反應的相關指導，請參閱 Office VBA 支援與意見反應。

  • 上次更新時間：