KeyBindings.Add 方法 (Word)

會傳回 KeyBinding 物件代表巨集、 內建命令、 字型、 自動圖文集項目、 樣式或符號的新快速鍵。

語法

運算式。新增 (KeyCategory、Command、KeyCode、KeyCode2、CommandParameter)

需要 expression。 代表 'KeyBindings' 集合的變數。

參數

名稱 必要/選用 資料類型 描述
KeyCategory 必要 WdKeyCategory 代表鍵設定的類別。
Command 必要 String 指定之按鍵組合執行的命令。
KeyCode 必要 Long 使用其中一個 WdKey 常數指定索引鍵。
KeyCode2 選用 Variant 使用其中一個 WdKey 常數指定第二個按鍵。
CommandParameter 選用 Variant Command 指定之命令所需的其他文字 (如果有的話)。 如需詳細資訊,請參閱下面的「備註」部分。

傳回值

KeyBinding

註解

使用 BuildKeyCode 方法建立 KeyCode 或 KeyCode2 引數。

在下表中,左欄包含需要命令值的命令,而右欄則說明您必須執行的動作,才能為每個命令指定 CommandParameter。 (在 [ 自訂鍵盤 ] 對話方塊 ([ 工具 ]) 功能表中,指定 CommandParameter 的對等動作是在 [ 命令 ] 方塊中選取下列其中一個命令時出現的清單方塊中選取項目 )

如果命令設為 CommandParameter 就必須是
Borders 、 Color 或 Shading 以文字指定之數字,對應於包含值之清單方塊中所選設定的位置,其中 0 (零) 代表第一個項目,1 代表第二個項目,依此類推
Columns 介於 1 到 45 的數字 - 以文字指定,對應至您想要套用的欄數
Condensed 介於 0.1 點至 12.75 點之間的文字度量值,以 0.05 點累加方式指定 (72 點 = 1 英吋)。
Expanded 介於 0.1 點至 12.75 點之間的文字度量值,以 0.05 點累加方式指定 (72 點 = 1 英吋)。
FileOpenFile 要開啟之檔案的路徑和檔名。 如果未指定路徑,就使用目前的資料夾。
Font Size 正數文字度量值,以 0.5 點累加方式指定 (72 點 = 1 英吋)。
Lowered 或 Raised 介於 1 點至 64 點之間的文字度量值,以 0.5 點累加方式指定 (72 點 = 1 英吋)。
Symbol 透過串連 chr () 指令和符號字型 (例如 Chr(167) & "Symbol") 名稱所建立的字串

範例

這則範例會將 CTRL+ALT+W 按鍵組合加入至 FileClose 命令。 此自訂鍵盤會儲存在 Normal 範本中。

CustomizationContext = NormalTemplate 
KeyBindings.Add _ 
    KeyCategory:=wdKeyCategoryCommand, _ 
    Command:="FileClose", _ 
    KeyCode:=BuildKeyCode(wdKeyControl, wdKeyAlt, wdKeyW)

本範例會將 ALT + F4 按鍵組合加入至 Arial 字型,然後 KeyBindings 集合中顯示的項目數。 然後範例會清除 ALT + F4 組合鍵 (將它傳回成預設設定),並重新顯示 KeyBindings 集合中的項目數。

CustomizationContext = ActiveDocument.AttachedTemplate 
Set myKey = KeyBindings.Add(KeyCategory:=wdKeyCategoryFont, _ 
    Command:="Arial", KeyCode:=BuildKeyCode(wdKeyAlt, wdKeyF4)) 
MsgBox KeyBindings.Count & " keys in KeyBindings collection" 
myKey.Clear 
MsgBox KeyBindings.Count & " keys in KeyBindings collection"

這則範例會將 CTRL+ALT+S 按鍵組合加入至 Font 命令,將字型大小指定為 8 點。

CustomizationContext = NormalTemplate 
KeyBindings.Add KeyCategory:=wdKeyCategoryCommand, _ 
    Command:="FontSize", _ 
    KeyCode:=BuildKeyCode(wdKeyControl, wdKeyAlt, wdKeyS), _ 
    CommandParameter:="8"

這則範例會將 CTRL+ALT+H 按鍵組合加入至使用中文件內的標題 1 樣式。

CustomizationContext = ActiveDocument 
KeyBindings.Add KeyCategory:=wdKeyCategoryStyle, _ 
    Command:="Heading 1", _ 
    KeyCode:=BuildKeyCode(wdKeyControl, wdKeyAlt, wdKeyH)

這則範例會將 CTRL+ALT+O 按鍵組合加入至名為 "Hello" 的自動圖文集項目。

CustomizationContext = ActiveDocument 
KeyBindings.Add KeyCategory:=wdKeyCategoryAutoText, _ 
    Command:="Hello", _ 
    KeyCode:=BuildKeyCode(wdKeyControl, wdKeyAlt, wdKeyO)

另請參閱

KeyBindings 集合物件

支援和意見反應

有關於 Office VBA 或這份文件的問題或意見反應嗎? 如需取得支援服務並提供意見反應的相關指導,請參閱 Office VBA 支援與意見反應。