SharePoint.Contents

Sintaxe

SharePoint.Contents(url as text, optional options as nullable record) as table

Sobre

Retorna uma tabela hierárquica que contém as pastas e arquivos encontrados no site de SharePoint especificado. url A tabela mostra os itens no nível atual e não retorna recursivamente todos os arquivos no site. Para pastas, a Content coluna contém uma tabela aninhada que pode ser usada para navegar até o conteúdo da pasta. Para arquivos, a Content coluna contém o conteúdo do arquivo como um valor binário. Para retornar uma tabela simples de todos os arquivos no site e suas subpastas, use SharePoint.Files. Cada linha também contém as Namecolunas, , Extension, Date accessedDate modified, Date createdAttributese Folder Path , As linhas de pasta têm um valor vazio Extension . Date accessed é null para pastas e arquivos. O Folder Path valor é a URL absoluta da pasta que contém o item. A URL do site não pode conter uma cadeia de caracteres de consulta ou um fragmento. options pode ser especificado para controlar as seguintes opções:

  • ApiVersion: um número (14 ou 15) ou o texto "Auto" que especifica a versão da API do SharePoint a ser usada para este site. Quando não especificado, a API versão 14 é usada. Quando Auto for especificado, a versão do servidor será descoberta automaticamente, se possível, caso contrário, a versão padrão será 14. Sites do SharePoint não em inglês exigem pelo menos a versão 15.
  • Implementation: opcional. Especifica qual versão do conector do SharePoint usar. Os valores aceitos são "2,0" ou nulos. Se o valor for "2.0", a implementação 2.0 do conector do SharePoint será usada. Se o valor for nulo, a implementação original do conector do SharePoint será usada.

Para SharePoint.Contents, a implementação original dá ApiVersion suporte aos valores 14, 15 e "Auto". Se ApiVersion não for especificado, a versão 14 será usada. Com a implementação 2.0, ApiVersion não é necessário especificar porque a API versão 15 é usada automaticamente. Não há suporte para a API versão 14 com a implementação 2.0.

Exemplo 1

Retorne o conteúdo de SharePoint de nível superior usando a implementação original. Como nenhuma opção é especificada, a versão 14 da API é usada.

Usage

SharePoint.Contents("https://contoso.sharepoint.com/sites/Contoso")

Output

A hierarchical table containing the top-level folders and files in the site.

Exemplo 2

Use a implementação original com a seleção automática de API para retornar todos os .xlsx arquivos na biblioteca de Documentos Compartilhados. A comparação de extensão não diferencia maiúsculas de minúsculas.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    ExcelWorkbooks = Table.SelectRows(
        SharedDocuments,
        each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
in
    ExcelWorkbooks

Output

A table containing only the files in the Shared Documents library whose Extension value is .xlsx.

Exemplo 3

Use a implementação 2.0 para retornar o conteúdo imediato da pasta Relatórios na biblioteca de Documentos Compartilhados. A implementação 2.0 usa a API versão 15 por padrão.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content]
in
    Reports

Output

A hierarchical table containing the immediate folders and files in the Reports folder.

Exemplo 4

Retorne o conteúdo binário de Budget.xlsx navegando no conteúdo hierárquico do site.

Usage

let
    Source = SharePoint.Contents(
        "https://contoso.sharepoint.com/sites/Contoso",
        [Implementation = "2.0"]
    ),
    SharedDocuments = Source{[Name = "Shared Documents"]}[Content],
    Reports = SharedDocuments{[Name = "Reports"]}[Content],
    Budget = Reports{[Name = "Budget.xlsx"]}[Content]
in
    Budget

Output

The binary content of Budget.xlsx.

  • Última atualização em