SharePoint.Files

Sintaxe

SharePoint.Files(url as text, optional options as nullable record) as table

Sobre

Retorna uma tabela que contém uma linha para cada arquivo encontrado no site de SharePoint especificado, urlincluindo arquivos em subpastas. Ao contrário SharePoint.Contents, essa função retorna uma tabela simples e não inclui linhas para pastas. A URL do site não pode conter uma cadeia de caracteres de consulta ou um fragmento. Cada linha contém o conteúdo binário do arquivo nos metadados de Content coluna e arquivo nas Namecolunas , , Extension, Date accessed, AttributesDate modifiedDate createde Folder Path colunas. O Folder Path valor é a URL absoluta da pasta que contém o arquivo. options pode ser especificado para controlar as seguintes opções:

• ApiVersion: um número (14 ou 15) ou o texto "Auto" que especifica a versão da API do SharePoint a ser usada para este site. Quando não especificado, a API versão 14 é usada. Quando Auto for especificado, a versão do servidor será descoberta automaticamente, se possível, caso contrário, a versão padrão será 14. Sites do SharePoint não em inglês exigem pelo menos a versão 15.

Exemplo 1

Liste o nome, a extensão de arquivo e a URL da pasta para cada arquivo no site SharePoint contoso usando a seleção automática de API.

Usage

let
    Source = SharePoint.Files(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SelectedColumns = Table.SelectColumns(
        Source,
        {"Name", "Extension", "Folder Path"}
    )
in
    SelectedColumns

Output

A table containing the name, extension, and absolute folder URL for each file in the site and its subfolders.

Exemplo 2

Retorne todos os arquivos com a .xlsx extensão do site SharePoint contoso. Este exemplo usa a API versão 15, que funciona com sites de SharePoint em inglês e não inglês. A comparação de extensão não diferencia maiúsculas de minúsculas, portanto, também corresponde .XLSX.

Usage

let
    Source = SharePoint.Files(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = 15]
    ),
    ExcelWorkbooks = Table.SelectRows(
      Source,
      each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
  in
    ExcelWorkbooks

Output

A table containing every .xlsx file in the site and its subfolders.

Exemplo 3

Retornar somente os arquivos armazenados diretamente na Shared Documents/Reports pasta. Uma correspondência exata Folder Path exclui arquivos em subpastas.

Usage

let
    Source = SharePoint.Files("https://contoso.sharepoint.com/sites/Contoso"),
    ReportsFiles = Table.SelectRows(
        Source,
        each [Folder Path] = "https://contoso.sharepoint.com/sites/Contoso/Shared Documents/Reports/"
    )
in
    ReportsFiles

Output

A table containing only the files stored directly in the Reports folder.

Exemplo 4

Retorne o conteúdo binário de Budget.xlsx da pasta Documentos Compartilhados/Relatórios.

Usage

let
    Source = SharePoint.Files("https://contoso.sharepoint.com/sites/Contoso"),
    Budget = Source{
      [
        Name = "Budget.xlsx",
        #"Folder Path" = "https://contoso.sharepoint.com/sites/Contoso/Shared Documents/Reports/"
      ]
    }[Content]
  in
    Budget

Output

The binary content of Budget.xlsx.